media-video/linux-uvc/linux-uvc-0.1.0_pre41.ebuild

linux-uvc-0.1.0_pre41.ebuild (text/plain), 2.16 KB, created by Armando Di Cianno on 2006-07-23 16:11:58 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit subversion eutils linux-mod linux-info

DESCRIPTION="Linux driver and user-space tools for USB Video Class devices."
HOMEPAGE="http://linux-uvc.berlios.de/"
LICENSE="GPL"
KEYWORDS="~x86"
SLOT="0"
IUSE="isight"
DEPEND="isight? dev-libs/libusb"
ESVN_REPO_URI="http://svn.berlios.de/svnroot/repos/linux-uvc/linux-uvc/trunk/"
ESVN_OPTIONS="-r ${PV/*_pre}"
MODULE_NAMES="uvcvideo(usb/media)"
BUILD_TARGETS="uvcvideo"
# Makefile is broken, and cannot run in parallel mode
MAKEOPTS="-j1"

pkg_setup() {
	linux-mod_pkg_setup
	ewarn "This is SVN checkout build -- against revision: ${PV/*_pre}"
	ewarn "If something is broken, you should get involved, and report"
	ewarn "back to the mailing list [e-mail]"

	if use isight; then
		MODULESD_UVCVIDEO_ENABLED="yes"
		MODULESD_UVCVIDEO_ADDITIONS=( "pre-install uvcvideo /usr/sbin/isight-firmware-tool /lib/firmware/AppleUSBVideoSupport" )
	fi

	ebeep 3
}

src_unpack() {
	subversion_src_unpack
	cd ${S}
	if use isight; then
		epatch ${FILESDIR}/41-001-isight.patch

		# Remove the next section when the stable libusb is >0.1.10a
		#   and it installs a pkg-config .pc file
		sed -i \
			-e "s/\`pkg-config --cflags --libs libusb\`/\`libusb-config --libs\`/" \
			${S}/Makefile || die "sed failed"
	fi
}

src_compile() {
	linux-mod_src_compile

	if use isight; then
		cd ${S}
		emake extract || die "Could not build iSight firmware tool."
	fi
}

src_install() {
	linux-mod_src_install
	
	if use isight; then
		cd ${S}
		newsbin extract isight-firmware-tool
	fi
}

pkg_postinst() {
	linux-mod_pkg_postinst
	ewarn "***"
	ewarn "Don't forget to look at the mailing lists for this driver"
	ewarn "They can be found at [e-mail]"

	if use isight; then
		einfo "Using iSight cameras, you *must* install the firmware to /lib/firmware, for e.g:"
		einfo "  mkdir -p /lib/firmware"
		einfo "  cp /\${OSX_MOUNT}/System/Library/Extensions/IOUSBFamily.kext/Contents/PlugIns/AppleUSBVideoSupport.kext/Contents/MacOS/AppleUSBVideoSupport /lib/firmware"
		einfo "Check /etc/modules.d/uvcvideo for more info."
	fi
}