# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs versionator games

MY_PV=$(delete_all_version_separators)
MY_PV=${MY_PV/alpha/}
DATE="20060301"
dir=${GAMES_DATADIR}/${PN}
libdir=${GAMES_LIBDIR}/${PN}

DESCRIPTION="Multiplayer-only paintball game based on the Quake 2 engine"
HOMEPAGE="http://www.planetquake.com/digitalpaint/"
SRC_URI="mirror://sourceforge/${PN}/${PN}_build${MY_PV}_linux_full.tar.gz
	mirror://sourceforge/${PN}/${PN}0_alpha${MY_PV}_src_${DATE}.zip"

# See license.txt
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="debug ipv6"

#QA_EXECSTACK="${GAMES_BINDIR:1}/${PN}"
QA_EXECSTACK="${dir:1}/${PN}"

UIRDEPEND="media-libs/jpeg
	media-libs/libogg
	virtual/opengl
	|| ( (
			x11-libs/libX11
			x11-libs/libXext
			x11-libs/libXxf86dga
			x11-libs/libXxf86vm )
		virtual/x11 )"
UIDEPEND="|| ( (
			x11-proto/xf86dgaproto
			x11-proto/xf86vidmodeproto
			x11-proto/xproto )
		virtual/x11 )"
RDEPEND="${UIRDEPEND}"
DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	mv -f *.txt docs
	rm docs/gnu.txt

	mv pball/configs .
	touch configs/{config.cfg,serverlist.dat}
}

src_compile() {
	yesno() { useq $1 && echo YES || echo NO ; }

	# Needed for a3d to compile
	mkdir -p release/a3d

	local target="build_release"
	use debug && target="build_debug"

	# Only working graphics mode is OpenGL
	# Only working sound mode is OSS
	emake -j1 "${target}" \
		SDLDIR="/usr/$(get_libdir)" \
		HAVE_IPV6=$(yesno ipv6) \
		CC="$(tc-getCC)" \
		BUILD_DEBUG_DIR=release \
		BUILD_RELEASE_DIR=release \
		|| die "emake failed"
}

src_install() {
	# Should really be dogamesbin
	#dogamesbin "${S}"/release/${PN} || die "dogamesbin ${PN} failed"
	exeinto "${dir}"
	doexe "${S}"/release/${PN} || die "doexe ${PN} failed"
	games_make_wrapper ${PN} ./${PN} "${dir}"

	# Should really be into ${libdir}
	# Don't get option of *compiling* pball/gamei386.so
	exeinto "${dir}"
	doexe "${S}"/release/*.so || die "doexe *.so failed"

	insinto "${dir}"
	doins -r ace baseq2 locs pball || die "doins -r failed"

	# No icon
	make_desktop_entry ${PN} "Paintball 2"

	dodoc docs/*

	# The game should be writing to ~/.${PN}/
	local state_dir=${GAMES_STATEDIR}/${PN}
	insinto "${state_dir}"
	doins configs/* || die "doins configs failed"

	dosym "${state_dir}" "${dir}/pball/configs" || die "dosym configs failed"
	dosym "${state_dir}/serverlist.dat" "${dir}/pball/serverlist.dat" \
		|| die "dosym serverlist.dat failed"

	prepgamesdirs

	fperms -R g+w "${state_dir}" || die "fperms ${state_dir} failed"
}