Munin 1.3.2 unfinished ebuild

munin-1.3.2.ebuild (text/plain), 2.78 KB, created by Allen Parker on 2006-07-10 00:14:47 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_P=munin-${PV}
S=${WORKDIR}/${MY_P}

DESCRIPTION="Munin Server Monitoring version ${PV}"
HOMEPAGE="http://munin.sourceforge.net"
SRC_URI="mirror://sourceforge/munin/${PN}_${PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc nodeonly"
DEPEND_COMMON="dev-lang/perl
        net-analyzer/rrdtool
        dev-perl/net-server
        sys-process/procps
        !nodeonly? ( dev-perl/HTML-Template
        perl-core/Getopt-Long
        perl-core/Storable )"
DEPEND="${DEPEND_COMMON}
        doc? ( app-text/htmldoc
        app-text/html2text )"
RDEPEND="${DEPEND_COMMON}
        virtual/cron"

src_unpack() {
        if use nodeonly; then
                ewarn "You've chosen to install munin without graphing support."
                ewarn "If you aren't planning on using another installation to poll this installtion,"
                ewarn "you should immediately cancel, set USE=\"-nodeonly\" and re-emerge munin."
        fi
        unpack ${A}
        cd ${S}

        epatch ${FILESDIR}/${PN}-testing.patch || die "epatch failed"
}

src_compile() {
        emake build || die "compile failed"
}

src_install() {
        use doc && { emake DESTDIR="${D}" install-doc install-man || die "install docs failed" }
        emake DESTDIR="${D}" install-main || die "install main failed"
        emake DESTDIR="${D}" install-node install-node-plugins || die "install node failed"
        fowners munin:munin /var/log/munin
        fowners munin:munin /var/lib/munin

        # make sure we've got everything in the correct directory
        if ! use nodeonly; then
                insinto /var/lib/munin
                newins ${FILESDIR}/munin.cron crontab
        fi
        newinitd ${FILESDIR}/munin-init.d munin-node
}

pkg_setup() {
        enewgroup munin
        enewuser munin 177 -1 /var/lib/munin munin
}

pkg_config() {
        einfo "Press enter to install the crontab for munin from /var/lib/munin/crontab" ; read
        crontab -l -u munin | grep --silent '.*'
        if [ $? -eq 1 ]; then
                crontab -u munin /var/lib/munin/crontab
        else
                eerror "Crontab already install for user munin. Not overwriting."
        fi
}

pkg_postinst() {
        einfo ""
        if use nodeonly; then
                einfo "You've chosen not to include munin's graphing features."
        else
                einfo "You've chosen to install munin's local graphing features. To have munin's cronjob"
                einfo "automatically configured for you, please emerge --config net-analyzer/munin"
        fi
        einfo "Please start munin-node via /etc/init.d/munin-node."
}