neon with socks support

neon-0.26.1.ebuild (text/plain), 1.53 KB, created by Steve Arnold on 2006-07-04 16:29:20 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/neon/neon-0.25.5.ebuild,v 1.3 2006/04/21 03:41:51 flameeyes Exp $

inherit libtool

DESCRIPTION="HTTP and WebDAV client library"
HOMEPAGE="http://www.webdav.org/neon/"
SRC_URI="http://www.webdav.org/neon/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc-macos ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="expat gnutls nls socks5 ssl static zlib"

DEPEND="expat? ( dev-libs/expat )
	!expat? ( dev-libs/libxml2 )
	socks5? ( net-proxy/dante )
	zlib? ( sys-libs/zlib )
	gnutls? ( >=net-libs/gnutls-1.0.22 )
	!gnutls? ( ssl? ( >=dev-libs/openssl-0.9.6f ) )"

src_unpack() {
	unpack ${A}
	if use userland_Darwin ; then
		sed -i -e "s:GXX:GCC:g" ${S}/configure || die "sed failed"
	fi

	elibtoolize
}

src_compile() {
	local myconf=""
	if use expat; then
	    myconf="${myconf} --with-expat"
	else
	    myconf="${myconf} --with-xml2"
	fi

	if use gnutls; then
	    myconf="${myconf} --with-ssl=gnutls"
	elif use ssl; then
	    myconf="${myconf} --with-ssl=openssl"
	fi
	! use nls && myconf="${myconf} --disable-nls"
	#if ! use static && myconf="${myconf} --disable-static"

	econf \
		--enable-shared \
		--without-gssapi \
		$(use_with zlib) \
		$(use_enable socks5 socks) \
		${myconf} \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	make DESTDIR=${D} install || die 'install failed'
	dodoc AUTHORS BUGS ChangeLog NEWS README THANKS TODO doc/*
}