# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/groff/groff-1.19.1-r2.ebuild,v 1.16 2005/09/29 07:57:59 usata Exp $

inherit eutils flag-o-matic toolchain-funcs

#MB_PATCH="groff_1.18.1-7" #"${P/-/_}-7"
DESCRIPTION="Text formatter used for man pages"
HOMEPAGE="http://www.gnu.org/software/groff/groff.html"
SRC_URI="mirror://gnu/groff/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 m68k mips ppc ppc64 s390 sh sparc x86"
IUSE="X"

DEPEND=">=sys-apps/texinfo-4.7-r1
	!app-i18n/man-pages-ja"
PDEPEND=">=sys-apps/man-1.5k-r1"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Fix problems with make install
	epatch "${FILESDIR}"/${P}-make-install.patch

	# Fix make dependencies so we can build in parallel
	epatch "${FILESDIR}"/${P}-parallel-make.patch
	
	# Fix problems with russian man pages
	epatch "${FILESDIR}"/${P}-nroff-manpage.patch

	# Make sure we can cross-compile this puppy
	if tc-is-cross-compiler ; then
		sed -i \
			-e '/^GROFFBIN=/s:=.*:=/usr/bin/groff:' \
			-e '/^TROFFBIN=/s:=.*:=/usr/bin/troff:' \
			-e '/^GROFF_BIN_PATH=/s:=.*:=:' \
			contrib/mom/Makefile.sub \
			doc/Makefile.in \
			doc/Makefile.sub || die "cross-compile sed failed"
	fi
}

src_compile() {
	# Fix problems with not finding g++
	tc-export CC CXX

	# -Os causes segfaults, -O is probably a fine replacement
	# (fixes bug 36008, 06 Jan 2004 agriffis)
	replace-flags -Os -O

	# -march=2.0 makes groff unable to finish the compile process
	use hppa && replace-cpu-flags 2.0 1.0

	# CJK doesnt work yet with groff-1.19
	#	$(use_enable cjk multibyte)

	# many fun sandbox errors with econf
	myconf="--host=${CHOST} \
		--prefix=/usr \
		--mandir=/usr/share/man \
		--infodir=\${inforoot} \
		--with-appresdir=/etc/X11/app-defaults"

	if use X; then
	    myconf="$myconf --with-x"
	fi

	./configure ${myconf} || die
	emake || die
}

src_install() {
	dodir /usr /usr/share/doc/${PF}/{examples,html}
	make \
		prefix="${D}"/usr \
		manroot="${D}"/usr/share/man \
		inforoot="${D}"/usr/share/info \
		docdir="${D}"/usr/share/doc/${PF} \
		root="${D}" \
		install || die
	# The following links are required for xman
	dosym eqn /usr/bin/geqn
	dosym tbl /usr/bin/gtbl
	dosym soelim /usr/bin/zsoelim
#	dobin "${FILESDIR}"/nroff

	dodoc BUG-REPORT ChangeLog FDL MORE.STUFF NEWS \
		PROBLEMS PROJECTS README REVISION TODO VERSION

}