transmission-0.6.1.ebuild

transmission-0.6.1.ebuild (text/plain), 1000 bytes, created by Alex Tarkovsky on 2006-07-01 00:40:40 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-0.6.ebuild,v 1.1 2006/06/28 01:22:39 squinky86 Exp $

inherit eutils

MY_P=${PN/t/T}-${PV}

DESCRIPTION="A lightweight BitTorrent client"
HOMEPAGE="http://transmission.m0k.org"
SRC_URI="http://download.m0k.org/transmission/files/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gtk ssl"

DEPEND="sys-devel/gettext
	gtk? ( >=x11-libs/gtk+-2.6 )
	ssl? ( dev-libs/openssl )"

S="${WORKDIR}/${MY_P}"

src_compile() {
	econf $(use_enable ssl openssl) \
		$(use_enable gtk) || die "configure failed"
	emake || die "emake failed"
}

src_install() {
	dobin cli/transmissioncli

	if use gtk ; then
		dobin gtk/transmission-gtk
		doicon "${FILESDIR}/transmission.png"
		make_desktop_entry "transmission-gtk" "${PN/t/T}" "${PN}.png" \
			"Network;Internet;GNOME;GTK;X-Red-Hat-Base"
	fi
	dodoc AUTHORS NEWS README
}