# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$

inherit eutils python

MY_P=${P/pylucene/PyLucene-src}
S="${WORKDIR}/${MY_P}"

DESCRIPTION="Python bindings od Lucene search engine"
HOMEPAGE="http://pylucene.osafoundation.org/"
SRC_URI="http://downloads.osafoundation.org/PyLucene/src/${MY_P}.tar.gz"
RESTRICT="nomirror"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="virtual/python
	>=dev-lang/swig-1.3.24
	>=sys-devel/gcc-3.4
	|| ( app-admin/eselect-compiler sys-devel/gcc-config )"
RDEPEND=""
	
python_version

pkg_setup() {
	built_with_use sys-devel/gcc gcj || die "PyLucene requires gcj compiler"
}

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/${PN}-makefile.patch
}

src_compile() {
	make PYTHON_VER=${PYVER} \
	     PREFIX=/usr PREFIX_PYTHON=/usr SWIG=/usr/bin/swig GCJ_HOME=/usr \
		 CC=${CC-gcc} CXX=${CXX-g++} JCC=gcj JCCH=gcjh JAR=gcj-jar \
		 all || die
}

src_install() {
	if [ -f /usr/bin/gcc-config ] ; then
		GCC_LDPATH=`gcc-config -L`
	else
		GCC_LDPATH=`eselect compiler getval LDPATH`
	fi

	dodoc CHANGES CREDITS LICENSE README

	dodir /usr/lib/python${PYVER}/site-packages
	emake GCC_LDPATH=${GCC_LDPATH} PYTHON_VER=${PYVER} PREFIX_PYTHON=${D}/usr \
	      install || die
}