dvdauthorwizard-1.3.0.ebuild

dvdauthorwizard-1.3.0.ebuild (text/plain), 1.26 KB, created by Jakub Moc (RETIRED) on 2006-06-20 07:34:55 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_P="DVDAuthorWizard-${PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="KDE DVD Authoring Wizard."
HOMEPAGE="http://dvdauthorwizard.sourceforge.net/"
SRC_URI="mirror://sourceforge/dvdauthorwizard/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dvdr xine"

DEPEND=""
RDEPEND="|| ( >=kde-base/kommander-3.4.3 >=kde-base/kdewebdev-3.4.3 )
	 >=media-gfx/imagemagick-6.1
	 media-video/mjpegtools
	 media-sound/sox
	 >=media-video/dvdauthor-0.6
	 media-video/transcode
	 sys-devel/bc
	 dvdr? ( app-cdr/k3b )
	 xine? ( media-video/xine-ui )"


src_unpack() {
	unpack ${A}
	cd "${S}"
	cp "${FILESDIR}/${PN}.desktop" .
	sed -i -e "s:@InstallDir@:$(kde-config --prefix):" \
		    ${PN}.desktop || die "sed failed"
}

src_install() {
	INSTDIR="$(kde-config --prefix)"

	dodir ${INSTDIR}
	cp -r "${S}/share" "${D}${INSTDIR}"
	exeinto ${INSTDIR}/bin
	doexe bin/DVDAuthorWizard-Builder.sh
	insinto ${INSTDIR}/bin
	doins bin/DVDAuthorWizard.kmdr

	newicon share/apps/${PN}/Pictures/dvdlogo2.png ${PN}.png
	insinto /usr/share/applications/kde
	doins ${S}/${PN}.desktop

	dodoc Changelog README
	newdoc "Creating Chapters.txt" Creating_Chapters.txt
}