ebuild for 1.15.1

xdg-desktop-portal-gtk-1.15.1.ebuild (text/plain), 1.29 KB, created by Martin Wagner on 2024-03-28 14:13:34 UTC

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit systemd meson

MY_PV="${PV//_pre*}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="Backend implementation for xdg-desktop-portal using GTK+"
HOMEPAGE="https://flatpak.org/ https://github.com/flatpak/xdg-desktop-portal-gtk"
SRC_URI="https://github.com/flatpak/${PN}/releases/download/${MY_PV}/${MY_P}.tar.xz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 ~arm arm64 ~loong ~ppc ~ppc64 ~riscv x86"
IUSE="wayland X"

BDEPEND="
	dev-util/gdbus-codegen
	sys-devel/gettext
	virtual/pkgconfig
"

DEPEND="
	dev-libs/glib:2
	gnome-base/gsettings-desktop-schemas
	media-libs/fontconfig
	sys-apps/dbus
	>=sys-apps/xdg-desktop-portal-1.14.0
	x11-libs/cairo[X?]
	x11-libs/gdk-pixbuf:2
	x11-libs/gtk+:3[wayland?,X?]
"

RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_configure() {
	# As done in Fedora:
	# All backends that are disabled are instead provided by
	# xdg-desktop-portal-gnome to keep this package free of GNOME dependencies.
	# The appchooser and settings backends are enabled for non-GNOME GTK
	# applications.
	local emesonargs=(
		-D systemd-user-unit-dir="$(systemd_get_userunitdir)"
		-D appchooser=enabled
		-D settings=enabled
		-D lockdown=disabled
		-D wallpaper=disabled
	)
	meson_src_configure
}