# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit versionator games

MY_PV=$(replace_all_version_separators '_')
MY_P=SecondLife_${MY_PV}

DESCRIPTION="A 3D MMORPG virtual world entirely built and owned by its residents"
HOMEPAGE="http://secondlife.com/"
SRC_URI="http://secondlife.com/downloads/viewer/${MY_P}.tar.bz2"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="mirror strip"

RDEPEND="dev-libs/libgcrypt
	dev-libs/libgpg-error
	dev-libs/openssl
	media-libs/freetype
	media-libs/libogg
	media-libs/libsdl
	media-libs/libvorbis
	net-libs/gnutls
	net-misc/curl
	sys-libs/glibc
	sys-libs/zlib
	virtual/glu
	virtual/opengl
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"

S=${WORKDIR}/${MY_P}
dir=${GAMES_PREFIX_OPT}/${PN}
state_dir=${GAMES_STATEDIR}/${PN}

src_install() {
	local d

	exeinto "${dir}"
	doexe ${PN} && rm ${PN} || die "doexe ${PN} failed"
	for d in bin lib ; do
		exeinto "${dir}/${d}"
		doexe "${d}"/* && rm "${d}"/* || die "doexe ${d} failed"
	done

	for d in cache logs user_settings ; do
		keepdir "${state_dir}/${d}"
	done
	dosym "${state_dir}" "${dir}"/SecondLife

	insinto "${dir}"
	doins -r * || die "doins failed"

	games_make_wrapper ${PN} bin/${PN}-bin "${dir}" "${dir}"/lib
	newicon help/sl_logo.gif ${PN}.gif
	make_desktop_entry ${PN} "Second Life" ${PN}.gif

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	# Need to be able to write within the state directories
	chmod -R 770 "${state_dir}"/* || die "chmod failed"
}