Ebuild for mindterm 3.0.1

mindterm-3.0.1.ebuild (text/plain), 1.25 KB, created by Bryan Jacobs on 2006-05-27 07:27:46 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/mindterm/mindterm-2.4.2.ebuild,v 1.6 2006/02/19 00:04:52 betelgeuse Exp $

inherit eutils java-pkg

DESCRIPTION="A Java SSH Client"
HOMEPAGE="http://www.appgate.com/products/80_MindTerm/"
SRC_URI="http://www.appgate.com/products/80_MindTerm/110_MindTerm_Download/${P/-/_}-src.zip"

LICENSE="mindterm"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~amd64"
IUSE="doc examples"
RDEPEND=">=virtual/jre-1.3"
DEPEND=">=virtual/jdk-1.3
	app-arch/unzip
	dev-java/ant-core"
S=${WORKDIR}/${P/-/_}

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/stupidelse.diff
}

src_compile() {
	local antflags="mindterm.jar lite"
	use doc && antflags="${antflags} doc"
	ant ${antflags} || die "ant failed"

	# move javadoc location to install into proper location
	mv javadoc api
}

src_install() {
	java-pkg_dojar *.jar

	echo "#!/bin/sh" > ${PN}
	echo 'java -cp $(java-config -p mindterm) com.mindbright.application.MindTerm ${@}' >> ${PN}

	into /usr
	dobin ${PN}

	dodoc README.txt
	use doc && java-pkg_dohtml -r api

	if use examples; then
		dodir /usr/share/doc/${PF}/examples
		cp -r ${S}/examples/* ${D}/usr/share/doc/${PF}/examples
	fi
}