# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PN=warsow
MY_PV=${PV/_/}
F=${MY_PN}_${MY_PV}_linux.tar.gz

DESCRIPTION="Multiplayer FPS based on the Quake 2 engine"
HOMEPAGE="http://www.warsow.net/"
SRC_URI="ftp://ftp.multiplay.co.uk/pub/games/fps/${MY_PN}/game/linux/${F}
	http://www.fatalerror.be/${MY_PN}/${F}
	http://www.vermaele.be/${MY_PN}/${F}
	ftp://ftp.grolier.fr/pub/games/nofrag/${MY_PN}/${F}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
RESTRICT="strip"
IUSE=""

RDEPEND=">=media-libs/libsdl-1.2.8-r1
	>=media-libs/sdl-sound-1.0.1-r1
	sys-libs/glibc
	sys-libs/zlib
	virtual/opengl
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"
DEPEND="${RDEPEND}
	!games-fps/warsow
	app-arch/unzip"

S=${WORKDIR}/${MY_PN}
dir=${GAMES_PREFIX_OPT}/${MY_PN}

src_install() {
	local bins="warsow wsw_server"
	local ext icon="levelshots/wdm1.jpg"

	insinto "${dir}"
	exeinto "${dir}"

	# Remove copy of licence
	rm docs/gnu.txt

	doexe ${bins} && rm ${bins} || die "doexe failed"
	doins -r * || die "doins failed"

	# Extract an icon - doesn't show in Gnome though
	unzip basewsw/data0.pk3 "${icon}"
	ext=${icon##*.}
	newicon "${icon}" "${MY_PN}.${ext}"

	# The game will write to ~/.warsow/
	games_make_wrapper ${MY_PN} "./${MY_PN} +set fs_usehomedir 1" "${dir}"
	make_desktop_entry ${MY_PN} "Warsow" "${MY_PN}.${ext}"

	prepgamesdirs
}