keytouch-2.1.4.ebuild

keytouch-2.1.4.ebuild (text/plain), 1.75 KB, created by Tristan Heaven (RETIRED) on 2006-05-24 06:54:29 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Easily configure extra keyboard function keys"
HOMEPAGE="http://keytouch.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="kde"

RDEPEND=">=virtual/linux-sources-2.6
	>=x11-libs/gtk+-2
	x11-misc/xbindkeys
	kde? ( || (
		kde-base/kdesu
		kde-base/kdebase ) )
	!kde? ( x11-libs/gksu )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

SUBDIRS=". keytouch-config keytouch-keyboard"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Prevent sandbox violations
	sed -i 's/install-data-local//1' \
		keytouchd/Makefile.in \
		keytouch-init/Makefile.in \
		keytouch-acpid/Makefile.in \
		|| die "sed failed"
}

src_compile() {
	for d in ${SUBDIRS} ; do
		cd "${S}"/${d}
		econf --disable-dependency-tracking || die "econf ${d} failed"
		emake || die "emake ${d} failed"
	done
}

src_install() {
	doinitd "${FILESDIR}"/keytouch || die "doinitd failed"

	dodir /usr/share/keytouch
	for d in ${SUBDIRS} ; do
		cd "${S}"/${d}
		make DESTDIR="${D}" install \
			|| die "make install ${d} failed"
	done

	make_desktop_entry ${PN} keyTouch ${PN}.png System
	dosym /usr/share/keytouch/pixmaps/icon.png \
		/usr/share/pixmaps/${PN}.png

	dodoc AUTHORS ChangeLog
}

pkg_postinst() {
	echo
	einfo "To make this work, add \"keytouchd &\" to your"
	einfo "X startup programs and run"
	einfo "\"rc-update add keytouch default\""
	echo
	einfo "If support for your keyboard is not included in"
	einfo "this release, check for new keyboard files at"
	einfo "http://keytouch.sourceforge.net/dl-keyboards.html"
	echo
	einfo "x11-misc/keytouch-editor can be used to create"
	einfo "your own keyboard files."
	echo
}