From b50c3c727e6921c07f104b6f4c1f67d8755b1c8b Mon Sep 17 00:00:00 2001
From: Eli Schwartz <eschwartz93@gmail.com>
Date: Sun, 22 Oct 2023 23:31:40 -0400
Subject: [PATCH] app-arch/unrar: fix symlinked header shenanigans

UnRar is horrible proprietary Windows-oriented software, yes yes yes we
know. It's nonstandard and the build system is a mess. It doesn't
version the library soname, doesn't install headers, doesn't uninstall
the files it installs, etc. Every distributor of it hacks around this
differently, but there are a couple things that it would be good to be
consistent with.

In particular, a stable name is needed for:
- including the header
- passing link args to the compiler

The latter works fine, but the former does not. There's a rough
consensus to use "unrar/" to install headers, and other projects rely on
that (or fall back to "libunrar/"), but we do not install there, and the
place we do install to is not used even in ::gentoo.

Start installing to "unrar/" instead. This allows some software to work
that formerly did not, and should still work everywhere else that was
looking for "libunrar/" as that is kept as a compat symlink.

Closes: https://bugs.gentoo.org/916036
Signed-off-by: Eli Schwartz <eschwartz93@gmail.com>
---
 ...r-6.2.12.ebuild => unrar-6.2.12-r1.ebuild} | 21 +++++++++++++++++--
 1 file changed, 19 insertions(+), 2 deletions(-)
 copy app-arch/unrar/{unrar-6.2.12.ebuild => unrar-6.2.12-r1.ebuild} (62%)

diff --git a/app-arch/unrar/unrar-6.2.12.ebuild b/app-arch/unrar/unrar-6.2.12-r1.ebuild
similarity index 62%
copy from app-arch/unrar/unrar-6.2.12.ebuild
copy to app-arch/unrar/unrar-6.2.12-r1.ebuild
index c97982261acd..bb14028fb165 100644
--- a/app-arch/unrar/unrar-6.2.12.ebuild
+++ b/app-arch/unrar/unrar-6.2.12-r1.ebuild
@@ -1,62 +1,79 @@
 # Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 inherit multilib toolchain-funcs
 
 MY_PN="${PN}src"
 
 DESCRIPTION="Uncompress rar files"
 HOMEPAGE="https://www.rarlab.com/rar_add.htm"
 SRC_URI="https://www.rarlab.com/rar/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
 S="${WORKDIR}/unrar"
 
 LICENSE="unRAR"
 SLOT="0/6" # subslot = soname version
 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
 
 PATCHES=( "${FILESDIR}/${PN}-6.2.6-honor-flags.patch" )
 
 src_prepare() {
 	default
 
 	local sed_args=( -e "/libunrar/s:.so:$(get_libname ${PV%.*.*}):" )
 	if [[ ${CHOST} == *-darwin* ]] ; then
 		sed_args+=( -e "s:-shared:-dynamiclib -install_name ${EPREFIX}/usr/$(get_libdir)/libunrar$(get_libname ${PV%.*.*}):" )
 	else
 		sed_args+=( -e "s:-shared:& -Wl,-soname -Wl,libunrar$(get_libname ${PV%.*.*}):" )
 	fi
 	sed -i "${sed_args[@]}" makefile || die
 }
 
 src_configure() {
 	mkdir -p build-{lib,bin} || die
 	printf 'VPATH = ..\ninclude ../makefile' > build-lib/Makefile || die
 	cp build-{lib,bin}/Makefile || die
 }
 
 src_compile() {
 	unrar_make() {
 		emake AR="$(tc-getAR)" CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS}" STRIP=true "$@"
 	}
 
 	unrar_make CXXFLAGS+=" -fPIC" -C build-lib lib
 	ln -s libunrar$(get_libname ${PV%.*.*}) build-lib/libunrar$(get_libname) || die
 	ln -s libunrar$(get_libname ${PV%.*.*}) build-lib/libunrar$(get_libname ${PV}) || die
 
 	unrar_make -C build-bin
 }
 
 src_install() {
 	dobin build-bin/unrar
 	dodoc readme.txt
 
 	dolib.so build-lib/libunrar*
 
-	insinto /usr/include/libunrar${PV%.*.*}
+	# unrar doesn't officially install headers, but unofficially, software
+	# depends on it anyway. There is no standard for where to install them,
+	# but the most common location (shared by nearly all vendors) is "unrar".
+	# FreeBSD alone uses "libunrar". Gentoo formerly used "libunrar6" and
+	# had a compat symlink for FreeBSD, then passed the compat location in
+	# ./configure scripts e.g. for sys-fs/rar2fs. Software in the wild
+	# seems to expect either "unrar" or "libunrar".
+	# See: https://bugs.gentoo.org/916036
+	#
+	# We now use the "standard" (hah) location, and keep the compat symlink but
+	# change the destination. The version-suffixed location lacks utility, but
+	# we would keep it if we could, just in case -- unfortunately portage is
+	# buggy: https://bugs.gentoo.org/834600
+	#
+	# Hopefully, no one has ever actually used it and therefore this does not
+	# matter. The odds are on our side, since it periodically changed location
+	# arbitrarily.
+	insinto /usr/include/unrar
 	doins *.hpp
-	dosym libunrar${PV%.*.*} /usr/include/libunrar
+	dosym unrar /usr/include/libunrar
 
 	find "${ED}" -type f -name "*.a" -delete || die
 }
-- 
2.41.0