[patch] 0001-net-print-cups-filters-add-2.0.0.patch

0001-net-print-cups-filters-add-2.0.0.patch (text/plain), 3.55 KB, created by Sam James on 2023-09-24 05:25:20 UTC

From 4129287891c74b7461346dd01fdcf6920a46bfff Mon Sep 17 00:00:00 2001
From: Sam James <[e-mail]>
Date: Sun, 24 Sep 2023 06:16:56 +0100
Subject: [PATCH] net-print/cups-filters: add 2.0.0

See https://github.com/OpenPrinting/cups-filters/commit/808f439f73b947eb1b376e2c3d5c576e445de543.

Signed-off-by: Sam James <[e-mail]>
---
 net-print/cups-filters/Manifest               |  1 +
 .../cups-filters/cups-filters-2.0.0.ebuild    | 73 +++++++++++++++++++
 2 files changed, 74 insertions(+)
 create mode 100644 net-print/cups-filters/cups-filters-2.0.0.ebuild

diff --git a/net-print/cups-filters/Manifest b/net-print/cups-filters/Manifest
index 96b28980e6194..3e7f08806c56c 100644
--- a/net-print/cups-filters/Manifest
+++ b/net-print/cups-filters/Manifest
@@ -1 +1,2 @@
 DIST cups-filters-1.28.17.tar.xz 1516052 BLAKE2B 87258391901d55d9e59b06d54603d014e54d224a373529bd70fcd38cded9dc96c88ca73bcea63d7633c065caea3f9e3274cd450aec5f1bd90130d9a88c0d3421 SHA512 320544a48206165581adafb28dbef58f39c66bebd3641be3d180a692605349d9e6af6d464044db9f7bda17a67f4a079370d8cc880cd7873d684b2209882deb35
+DIST cups-filters-2.0.0.tar.xz 447648 BLAKE2B be5e2aab4eb921aa67bfcc93aa5f95a9f1fe1a269ed73d18273a0e9a3e816187e9e32750ba6521c3ab083c3c7b7a60bb1fa679e16d4a5917f911a4ba8d4b7207 SHA512 fc8ba3bbf92d5ede295884023d1c42422c4c250dbbf21c948f160a04ded3259784df4bd17eea64492f9417f866e566be1a9fcde47d29655cd4204ef4cc7af134
diff --git a/net-print/cups-filters/cups-filters-2.0.0.ebuild b/net-print/cups-filters/cups-filters-2.0.0.ebuild
new file mode 100644
index 0000000000000..8e242abc9ea87
--- /dev/null
+++ b/net-print/cups-filters/cups-filters-2.0.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+DESCRIPTION="Cups filters"
+HOMEPAGE="https://wiki.linuxfoundation.org/openprinting/cups-filters"
+SRC_URI="
+	https://github.com/OpenPrinting/cups-filters/releases/download/${PV}/${P}.tar.xz
+	https://www.openprinting.org/download/${PN}/${P}.tar.xz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="pdf +postscript test zeroconf"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=app-text/poppler-0.32[utils]
+	dev-libs/glib:2
+	>=net-print/cups-2.2.2
+	sys-devel/bc
+	pdf? ( app-text/mupdf:= )
+	postscript? ( >=app-text/ghostscript-gpl-9.09[cups] )
+	zeroconf? ( net-dns/avahi[dbus] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+	test? ( media-fonts/dejavu )
+"
+
+src_configure() {
+	local myeconfargs=(
+		--localstatedir="${EPREFIX}"/var
+		--with-fontdir="fonts/conf.avail"
+
+		--enable-foomatic
+		--enable-imagefilters
+		$(use_enable pdf mutool)
+		$(use_enable postscript ghostscript)
+		$(use_enable zeroconf avahi)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use postscript; then
+		# workaround: some printer drivers still require pstoraster and pstopxl, bug #383831
+		dosym gstoraster /usr/libexec/cups/filter/pstoraster
+		dosym gstopxl /usr/libexec/cups/filter/pstopxl
+	fi
+
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+
+	cp "${FILESDIR}"/cups-browsed.init.d-r2 "${T}"/cups-browsed || die
+
+	if ! use zeroconf ; then
+		sed -i -e 's:need cupsd avahi-daemon:need cupsd:g' "${T}"/cups-browsed || die
+		sed -i -e 's:cups\.service avahi-daemon\.service:cups.service:g' "${S}"/utils/cups-browsed.service || die
+	fi
+
+	doinitd "${T}"/cups-browsed
+	systemd_dounit "${S}"/utils/cups-browsed.service
+}
-- 
2.42.0