x2-demo-1.4.01.ebuild

x2-demo-1.4.01.ebuild (text/plain), 1.37 KB, created by Paul Bredbury on 2006-05-17 12:58:07 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator games

DESCRIPTION="Open-ended space opera with trading, building & fighting"
HOMEPAGE="http://www.linuxgamepublishing.com/info.php?id=x2"
# Patches are in http://updatefiles.linuxgamepublishing.com/x2-demo/
SRC_URI="http://demofiles.linuxgamepublishing.com/x2/${PN}.run"

LICENSE="as-is
	GPL-2
	LGPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="primaryuri nostrip"

RDEPEND="media-libs/alsa-lib
	media-libs/libsdl
	media-libs/openal
	sys-libs/glibc
	sys-libs/zlib
	x11-libs/gtk+
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext
			x11-libs/libXi )
		virtual/x11 )"
DEPEND=""

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/${PN}

src_unpack() {
	einfo 'The "trailing garbage after EOF ignored" message is harmless.'
	unpack_makeself ${PN}.run
	unpack ./data.tar.gz
}

src_install() {
	exeinto "${dir}"
	doexe bin/Linux/x86/x2* || die "doexe failed"

	rm -r bin data.tar.gz lgp_* setup*

	insinto "${dir}"
	doins -r * || die "doins -r failed"
	keepdir "${dir}"/database

	# x2_demo.dynamic continually moans about "SIGABRT caught",
	# so use the static binary instead.
	games_make_wrapper ${PN} ./x2_demo "${dir}" "${dir}"
	newicon icon.xpm ${PN}.xpm
	make_desktop_entry ${PN} "X2 - The Threat Demo" ${PN}.xpm

	prepgamesdirs
}