x2-demo-1.4.01.ebuild

x2-demo-1.4.01.ebuild (text/plain), 1.82 KB, created by Paul Bredbury on 2006-05-15 14:16:51 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator games

PV_MAJOR=$(get_version_component_range 1-2)
MY_P=${PN}-${PV_MAJOR}-${PV}

DESCRIPTION="Open-ended space opera with trading, building & fighting"
HOMEPAGE="http://www.linuxgamepublishing.com/info.php?id=x2"

# Patches are in http://updatefiles.linuxgamepublishing.com/x2-demo/
SRC_URI="http://demofiles.linuxgamepublishing.com/x2/${PN}.run
	http://updatefiles.linuxgamepublishing.com/${PN}/${MY_P}-x86.run"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="primaryuri nostrip"

RDEPEND="media-libs/alsa-lib
	media-libs/libsdl
	media-libs/openal
	sys-libs/glibc
	sys-libs/zlib
	x11-libs/gtk+
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext
			x11-libs/libXi )
		virtual/x11 )"
DEPEND=">=dev-util/xdelta-1.1.3"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/${PN}

src_unpack() {
	unpack_makeself ${PN}.run
	unpack_makeself ${MY_P}-x86.run
	unpack ./data.tar.gz
}

src_install() {
	local f p exes="x2_demo x2_demo.dynamic"

	mv bin/Linux/x86/x2* .
	rm -r bin data.tar.gz setup*

	# Use xdelta instead of loki_patch, for reliability
	for p in data/*.0 ; do
		# Determine filename in current directory
		f=$(basename "${p}" ".0")
		xdelta patch "${p}" "${f}" "${f}.xdelta" || die "xdelta ${p} failed"
		mv -f "${f}.xdelta" "${f}"
	done
	rm -r data lgp_* *.sh patch*

	exeinto "${dir}"
	doexe ${exes} || die "doexe failed"
	rm ${exes}

	insinto "${dir}"
	doins -r * || die "doins -r failed"
	keepdir "${dir}"/database

	# x2_demo.dynamic continually moans about "SIGABRT caught",
	# so use the static binary instead.
	games_make_wrapper ${PN} ./x2_demo "${dir}" "${dir}"
	newicon icon.xpm ${PN}.xpm
	make_desktop_entry ${PN} "X2 - The Threat Demo" ${PN}.xpm

	prepgamesdirs
}