better ebuild for 2.0.1 version

dolibarr-2.0.1.ebuild (text/plain), 2.44 KB, created by Fab on 2006-05-09 08:45:50 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils webapp depend.php

DESCRIPTION="ERP/CRM for small and medium companies"
HOMEPAGE="http://dolibarrint.jexiste.fr/en/"

# It's NOT the real URI
SRC_URI="http://netfab.ifrance.com/download/${PN}/${PV}/${P}.tgz"

# The patchset...
SRC_URI="${SRC_URI}
	http://netfab.ifrance.com/download/${PN}/${PV}/gentoo-${P}-patchset.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE=""
DEPEND=""

pkg_setup() {
	webapp_pkg_setup
	
	# we check that PHP was compiled with the correct USE flags
	require_php_with_use curl gd mysql

}

src_unpack() {
	unpack ${A}
	
	cd ${S}

	einfo "Generating SQL file ..."
	cd mysql && emake mysql.sql &> /dev/null && cd ..

	# ================
	#     patchs
	# ================
	# 01_all_config-file-creation.patch
	#		create dolibarr configuration file
	#
	# 02_all_NAMES-latin1.patch
	# 		Database is in latin1.
	#
	# 03_all_default-lang.patch
	#		set default language to 'en_US' in generated SQL file.
	#
	# 05_all_installation-header.patch
	#		Fix installation's page header (iso-8859-1)
	#
	# 06_all_install-config.patch
	#		Don't need these inputs here :
	#		these steps will be done with the mysql's prompt.
	#
	# 07_all_install-skip-step2.patch
	#		Skip installation's step 2 : 
	#		we will create the database, all tables and datas
	#		with the mysql's prompt.
	#
	# 08_all_main-header.patch
	#		Fix main page header (iso-8859-1)

	EPATCH_SUFFIX="patch" epatch "${WORKDIR}/gentoo-patches"

}

src_install() {
	webapp_src_preinst

	cd ${S}

	webapp_sqlscript mysql mysql/mysql.sql

	local ARI="doc/install"
	local ARU="doc/user"

	# WARNING : install instructions are deprecated,
	# and documents are only in french.
	# Example : PEAR Base System is already included in dolibarr's code.
	local docs="
		README README-FR ChangeLog COPYING COPYRIGHT doc/Mysql
		${ARI}/dolibarr-install.pdf ${ARI}/dolibarr-install.txt
		${ARU}/dolibarr-user.pdf ${ARU}/dolibarr-user.txt"

	dodoc ${docs}

	dohtml ${ARI}/dolibarr-install-1.html ${ARI}/dolibarr-install-2.html \
			${ARI}/dolibarr-install-3.html ${ARI}/dolibarr-install.html

	einfo "Installing main files"
	cd htdocs
	cp -r . ${D}${MY_HTDOCSDIR}

	webapp_postinst_txt en ${FILESDIR}/${PV}/postinstall-en.txt

	# Set correct permissions on the configuration file
	webapp_hook_script ${FILESDIR}/conf-file-perms

	webapp_src_install
}