# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit wxwidgets subversion debug eutils

ESVN_REPO_URI="svn://svn.berlios.de/codeblocks/trunk"
ESVN_PROJECT="${P}"

WX_GTK_VER="2.6"

DESCRIPTION="free cross-platform C/C++ IDE"
HOMEPAGE="http://www.codeblocks.org/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

IUSE="contrib unicode"

RDEPEND=">=x11-libs/wxGTK-2.6.2*"

DEPEND="${RDEPEND}
	>=sys-devel/autoconf-2.5*
	>=sys-devel/automake-1.7*
	>=sys-devel/libtool-1.4*"

pkg_setup() {
	need-wxwidgets gtk2
	if use unicode ; then
		need-wxwidgets unicode
	fi
}

src_compile() {
	local myconf

	# we need ".svn" directories for build
	einfo "Syncing ${ESVN_STORE_DIR}/${ESVN_PROJECT}/${ESVN_REPO_URI##*/}/ into ${S}"
	rsync -a "${ESVN_STORE_DIR}/${ESVN_PROJECT}/${ESVN_REPO_URI##*/}/" "${S}" || die "${ESVN}: can't export to ${S}."

	myconf="${myconf}
		$(use_enable contrib)
		$(use_enable debug)"

	cd ${S}
	./bootstrap || die "bootstrap failed."

	econf ${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "Died in make install..."
}