ebuild also useable for 9999

scummvm-tools-2.7.0.ebuild (text/plain), 1.46 KB, created by jospezial on 2023-05-21 01:07:45 UTC

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
WX_GTK_VER=3.2-gtk3
inherit wxwidgets toolchain-funcs

DESCRIPTION="utilities for the SCUMM game engine"
HOMEPAGE="https://www.scummvm.org/ https://github.com/scummvm/scummvm-tools"
if [[ ${PV} == *9999* ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/scummvm/scummvm-tools"
else
	SRC_URI="https://downloads.scummvm.org/frs/scummvm-tools/${PV}/${P}.tar.xz"
	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
	S=${WORKDIR}/${P/_/}
fi

LICENSE="GPL-2+"
SLOT="0"
IUSE="flac iconv mad png vorbis"
RESTRICT="test" # some tests require external files

DEPEND="
	dev-libs/boost:=
	sys-libs/zlib
	x11-libs/wxGTK:${WX_GTK_VER}
	flac? ( media-libs/flac:= )
	iconv? ( virtual/libiconv media-libs/freetype:2 )
	mad? ( media-libs/libmad )
	png? ( media-libs/libpng:= )
	vorbis? ( media-libs/libvorbis )
"
RDEPEND="
	${DEPEND}
"
BDEPEND="
	virtual/pkgconfig
"

PATCHES=(
	"${FILESDIR}/${PN}-1.8.0-binprefix.patch"
)

src_prepare() {
	default

	rm -r *.bat dists/win32 || die
}

src_configure() {
	setup-wxwidgets
	tc-export CXX STRINGS

	# Not an autoconf script
	./configure \
		--disable-tremor \
		--enable-verbose-build \
		--mandir="${EPREFIX}/usr/share/man" \
		--prefix="${EPREFIX}/usr" \
		$(use_enable flac) \
		$(use_enable iconv) \
		$(use_enable iconv freetype2) \
		$(use_enable mad) \
		$(use_enable png) \
		$(use_enable vorbis) || die
}

src_install() {
	EXEPREFIX="${PN}-" default
}