x2-demo-1.4.01.ebuild

x2-demo-1.4.01.ebuild (text/plain), 1.96 KB, created by Paul Bredbury on 2006-05-04 13:51:21 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator games

PV_MAJOR=$(get_version_component_range 1-2)
MY_P=${PN}-${PV_MAJOR}-${PV}

DESCRIPTION="Open-ended space opera with trading, building & fighting"
HOMEPAGE="http://www.linuxgamepublishing.com/info.php?id=x2"

# Patches are in http://updatefiles.linuxgamepublishing.com/x2-demo/
SRC_URI="http://demofiles.linuxgamepublishing.com/x2/${PN}.run
	http://updatefiles.linuxgamepublishing.com/${PN}/${MY_P}-x86.run"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="primaryuri strip"

RDEPEND="media-libs/alsa-lib
	media-libs/libsdl
	media-libs/openal
	sys-libs/glibc
	sys-libs/zlib
	virtual/libc
	|| (
		(
			x11-libs/gtk+
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext
			x11-libs/libXi )
		virtual/x11 )"
DEPEND="games-util/loki_patch"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/${PN}

unpack_makeself() {
	# eutils cannot handle these files

	local arc="unpack.tar.bz2"
	local skip

	skip=$(grep -a offset=.*head.*wc "${DISTDIR}/${1}" | awk '{print $3}' | head -n 1)
	tail -n +${skip} "${DISTDIR}/${1}" | tail -n +2 > "${arc}"
	tar jxvf "${arc}" || die "unpack_makeself ${1} failed"
	rm "${arc}"
}

src_unpack() {
	unpack_makeself ${PN}.run
	unpack_makeself ${MY_P}-x86.run

	# Prepare files for patching
	unpack ./data.tar.gz
	mv bin/Linux/x86/x2* .
	rm -r bin data.tar.gz setup*
	loki_patch patch.dat . || die "loki_patch failed"
	rm -r data patch.dat lgp_* *.sh
}

src_install() {
	exeinto "${dir}"
	doexe x2_demo{,.dynamic} || die "doexe failed"
	rm x2_demo{,.dynamic}

	insinto "${dir}"
	doins -r * || die "doins -r failed"
	keepdir "${dir}"/database

	# x2_demo.dynamic continually moans about "SIGABRT caught",
	# so let's use the static binary instead.
	games_make_wrapper ${PN} ./x2_demo "${dir}" "${dir}"
	newicon icon.xpm ${PN}.xpm
	make_desktop_entry ${PN} "X2 - The Threat Demo" ${PN}.xpm

	prepgamesdirs
}