# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic

MY_P=${P/_alpha/-WIP}

DESCRIPTION="The Eggplant Ubiquitous Amiga Emulator"
HOMEPAGE="http://www.rcdrummond.net/uae/"
SRC_URI="http://www.rcdrummond.net/uae/${MY_P}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="X capslib gtk ncurses sdl svga"

DEPEND="app-cdr/cdrtools
	virtual/libc
	capslib? ( games-emulation/caps )
	gtk? ( >=x11-libs/gtk+-2.0.0 )
	ncurses? ( sys-libs/ncurses )
	svga? ( media-libs/svgalib )
	sdl? ( media-libs/libsdl )
	X? ( || ( (
			x11-libs/libXt
			x11-libs/libxkbfile
			x11-proto/xextproto
			x11-proto/xf86dgaproto
			x11-proto/xf86vidmodeproto
			x11-proto/xproto )
		virtual/x11 ) )"

S=${WORKDIR}/${MY_P}

src_compile() {
	local myconf

	# -O3 breaks compilation, GCC will eat all your RAM + Swap and die
	replace-flags "-O3" "-O2"
	use x86 && strip-flags "-msse" "-msse2"
	use ppc && strip-flags "-maltivec" "-mabi=altivec"
	use sdl && myconf="--with-sdl-sound --with-sdl-gfx"

	export WANT_AUTOMAKE=1.7
	export WANT_AUTOCONF=2.5

	./bootstrap.sh || die "bootstrap failed"

	econf ${myconf} \
		$(use_with capslib caps) \
		--enable-threads \
		--enable-aga \
		--enable-cdtv \
		--enable-cd32 \
		--enable-scsi-device \
		--enable-bsdsock-new \
		--with-libscg-includedir=/usr/include/scsilib \
		|| die "econf failed"

	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"

	# Rename executables, to prevent conflict with uae ebuild
	mv "${D}"/usr/bin/uae "${D}"/usr/bin/e-uae
	mv "${D}"/usr/bin/readdisk "${D}"/usr/bin/e-readdisk

	dodoc docs/* ChangeLog CHANGES README
}