# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: Exp $

inherit distutils

MY_P=${P/soya/Soya}
MY_PN=${PN/soya/Soya}
DESCRIPTION="A high-level 3D engine for Python, designed with games in mind"
HOMEPAGE="http://www.soya3d.org/"
SRC_URI="http://download.gna.org/soya/${MY_P}.tar.bz2
	doc? ( http://download.gna.org/soya/${MY_PN}Tutorial-0.10.2.tar.bz2 )
	examples? ( http://download.gna.org/soya/${MY_PN}Tutorial-0.10.2.tar.bz2 )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc"
IUSE="doc examples ode openal"

# Documented to need PIL (imaging) and pyrex
# pyrex isn't actually needed for normal building of non-cvs.
DEPEND="virtual/x11
	virtual/opengl
	>=dev-lang/python-2.4.2
	>=dev-python/imaging-1.1.5
	>=media-fonts/freefonts-0.10
	>=media-libs/cal3d-0.10
	>=media-libs/glew-1.3.3
	>=media-libs/freetype-2.1.5
	>=media-libs/libsdl-1.2.8
	>=media-libs/libpng-1.2.8
	ode? ( >=dev-games/ode-0.5 )"


RDEPEND="${DEPEND}
	>=dev-python/editobj-0.5.6
	openal? ( >=dev-python/pyopenal-0.1.4 )"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	rm ${S}/pudding/test.py	# This file shouldn't be installed
}

src_compile() {
	if ! use ode; then
		sed -i -e "s/^\(USE_ODE = \).*$/\1False/" setup.py || die "sed install.py failed"
	fi
	distutils_src_compile
}

src_install() {
	distutils_src_install
	if use doc; then
		cd ${WORKDIR}/${MY_PN}Tutorial-${PV}
		insinto /usr/share/doc/${PF}/docs
		doins -r doc/*
	fi
	if use examples; then
		cd ${WORKDIR}/${MY_PN}Tutorial-${PV}
		insinto /usr/share/doc/${PF}/examples
		doins -r tutorial/*
	fi
}