[patch] Ebuild for sddm 0.19.0

0001-Add-ebuild-for-x11-libs-sddm-0.19.0.patch (text/plain), 4.55 KB, created by mcendu on 2023-03-07 14:05:50 UTC

From 50b6868dea7a3fd28fb3dc670a9d376f11aa8a6d Mon Sep 17 00:00:00 2001
From: Nathan Du <[e-mail]>
Date: Tue, 7 Mar 2023 21:52:00 +0800
Subject: [PATCH] Add ebuild for x11-libs/sddm 0.19.0

Signed-off-by: Nathan Du <[e-mail]>
---
 x11-misc/sddm/Manifest           |   1 +
 x11-misc/sddm/sddm-0.19.0.ebuild | 117 +++++++++++++++++++++++++++++++
 2 files changed, 118 insertions(+)
 create mode 100644 x11-misc/sddm/sddm-0.19.0.ebuild

diff --git a/x11-misc/sddm/Manifest b/x11-misc/sddm/Manifest
index d1006dba1..411b8fd1b 100644
--- a/x11-misc/sddm/Manifest
+++ b/x11-misc/sddm/Manifest
@@ -1 +1,2 @@
 DIST sddm-0.18.1.tar.xz 3402972 BLAKE2B 99ab43d374e9a3d318f692a6d496d8a6d68927af3c8e8fc2208d7355ec90649a14758b39f5733dd32f942ed569de88085576d4f5f8666f4f97079e0fb6dcb99e SHA512 ff0637600cda2f4da1f643f047f8ee822bd9651ae4ccbb614b9804175c97360ada7af93e07a7b63832f014ef6e7d1b5380ab2b8959f8024ea520fa5ff17efd60
+DIST sddm-0.19.0.tar.xz 3406056 BLAKE2B 4f5c19928483a2ad6584d7d42745d32f6b8fd2e4c5b4a44ab79cb878d9c9fea05f2550b83da02d365f42f9ec4530041991dfdf01aaaf55a245621b22d9054818 SHA512 0a40816bc105a1e930fec2d65fabff0ae7e27c641235d90e41f6fbaa86af4bb774a9e30f7548ce2c6c791e6d4f8195b02afddedca60a9e7c77447702e728edc3
diff --git a/x11-misc/sddm/sddm-0.19.0.ebuild b/x11-misc/sddm/sddm-0.19.0.ebuild
new file mode 100644
index 000000000..cdcea2cf7
--- /dev/null
+++ b/x11-misc/sddm/sddm-0.19.0.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake linux-info systemd tmpfiles
+
+DESCRIPTION="Simple Desktop Display Manager"
+HOMEPAGE="https://github.com/sddm/sddm"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+elogind +pam systemd test"
+
+REQUIRED_USE="?? ( elogind systemd )"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	acct-group/sddm
+	acct-user/sddm
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	x11-base/xorg-server
+	x11-libs/libxcb:=
+	elogind? ( sys-auth/elogind )
+	pam? ( sys-libs/pam )
+	!pam? ( virtual/libcrypt:= )
+	systemd? ( sys-apps/systemd:= )
+	!systemd? ( sys-power/upower )
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!systemd? ( gui-libs/display-manager-init )
+"
+BDEPEND="
+	dev-python/docutils
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules:5
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.18.1-qt-5.15.2.patch"
+)
+
+pkg_setup() {
+	local CONFIG_CHECK="~DRM"
+	use kernel_linux && linux-info_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	if ! use test; then
+		sed -e "/^find_package/s/ Test//" -i CMakeLists.txt || die
+		cmake_comment_add_subdirectory test
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PAM=$(usex pam)
+		-DNO_SYSTEMD=$(usex '!systemd')
+		-DUSE_ELOGIND=$(usex 'elogind')
+		-DBUILD_MAN_PAGES=ON
+		-DDBUS_CONFIG_FILENAME="org.freedesktop.sddm.conf"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	newtmpfiles "${FILESDIR}/${PN}.tmpfiles" "${PN}.conf"
+
+	# Create a default.conf as upstream dropped /etc/sddm.conf w/o replacement
+	local confd="/usr/share/sddm/sddm.conf.d"
+	dodir ${confd}
+	"${D}"/usr/bin/sddm --example-config > "${D}/${confd}"/00default.conf \
+		|| die "Failed to create 00default.conf"
+
+	sed -e "/^InputMethod/s/qtvirtualkeyboard//" \
+		-e "/^ReuseSession/s/false/true/" \
+		-e "/^EnableHiDPI/s/false/true/" \
+		-i "${D}/${confd}"/00default.conf || die
+}
+
+pkg_postinst() {
+	tmpfiles_process "${PN}.conf"
+
+	elog "Starting with 0.18.0, SDDM no longer installs /etc/sddm.conf"
+	elog "Use it to override specific options. SDDM defaults are now"
+	elog "found in: /usr/share/sddm/sddm.conf.d/00default.conf"
+	elog
+	elog "NOTE: If SDDM startup appears to hang then entropy pool is too low."
+	elog "This can be fixed by configuring one of the following:"
+	elog "  - Enable CONFIG_RANDOM_TRUST_CPU in linux kernel"
+	elog "  - # emerge sys-apps/haveged && rc-update add haveged boot"
+	elog "  - # emerge sys-apps/rng-tools && rc-update add rngd boot"
+	elog
+	elog "For more information on how to configure SDDM, please visit the wiki:"
+	elog "  https://wiki.gentoo.org/wiki/SDDM"
+	if has_version x11-drivers/nvidia-drivers; then
+		elog
+		elog "  Nvidia GPU owners in particular should pay attention"
+		elog "  to the troubleshooting section."
+	fi
+
+	systemd_reenable sddm.service
+}
-- 
2.39.2