fbc-0.15b.ebuild

fbc-0.15b.ebuild (text/plain), 1.90 KB, created by Alexandru Toma on 2006-04-24 13:50:37 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PN="FreeBASIC"
FB_BIN_DIST="${WORKDIR}/${MY_PN}"

DESCRIPTION="Multi-platform BASIC compiler, syntax compatible with QuickBASIC"
HOMEPAGE="http://www.freebasic.net/"
# fbc is written in BASIC so we also need the binary distribution to compile it
SRC_URI="mirror://sourceforge/fbc/${PN}-v${PV}-src.zip
	mirror://sourceforge/fbc/${MY_PN}-v${PV}-linux.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="app-arch/unzip
	sys-libs/libtermcap-compat
	=sys-libs/libfb-0.15b"

RDEPEND="sys-libs/libtermcap-compat"

S="${WORKDIR}/src/compiler"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Patch makefile and lib dir paths in source files
	epatch "${FILESDIR}/fbc-0.15b-makefile.patch"
	epatch "${FILESDIR}/fbc-0.15b-gentoo-paths.patch"

	sed -i \
		-e "s:@GENTOO_GCC_LIB_PATH@:$(gcc-config -L):" \
		-e "s:@GENTOO_FREEBASIC@:${FB_BIN_DIST}/bin/linux:" \
		fbc_linux.bas || die "sed fbc_linux.bas failed"

	sed -i \
		-e "s:exepath( ) + ::" \
		*.bas || die "sed *.bas failed"
}

src_compile() {
	# fbc hardcodes the paths of the libraries it links against inside the binary.
	# When it is first compiled (no previous installation) it links against the
	# libraries in "${FB_BIN_DIST}/lib/linux". To get it to link against the system
	# libraries, we recompile it a second time.
	# FBCFLAGS are similar to CFLAGS/CXXFLAGS and can be user defined.
	if has_version games-engines/fbc ; then
		emake FBCFLAGS="${FBCFLAGS}" FBC="fbc" || die "first emake failed"
	else
		emake FBCFLAGS="${FBCFLAGS}" FBC="${FB_BIN_DIST}/fbc" || die "second emake failed"
		cp fbc_new fbc
		emake clean || die "emake clean failed"
		emake FBCFLAGS="${FBCFLAGS}" FBC="./fbc" || die "final emake failed"
	fi
}

src_install() {
	newbin fbc_new fbc || die "newbin failed"
	dodoc TODO.txt ../../${MY_PN}/{changelog.txt,readme.txt}
}