app-office/dia/dia-0.95.ebuild

dia-0.95.ebuild (text/plain), 1.36 KB, created by Damien Thébault on 2006-04-22 15:16:46 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils gnome2 libtool

DESCRIPTION="Diagram/flowchart creation program"
HOMEPAGE="http://www.gnome.org/projects/dia/"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~alpha ~amd64 ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="cairo gnome gnomeprint png python static zlib"

RDEPEND=">=x11-libs/gtk+-2
	>=x11-libs/pango-1.1.5
	>=dev-libs/libxml2-2.3.9
	>=dev-libs/libxslt-1
	>=media-libs/freetype-2.0.9
	dev-libs/popt
	zlib? ( sys-libs/zlib )
	png? ( media-libs/libpng
		>=media-libs/libart_lgpl-2 )
	gnome? ( >=gnome-base/libgnome-2.0
		>=gnome-base/libgnomeui-2.0 )
	python? ( >=dev-lang/python-1.5.2
		>=dev-python/pygtk-1.99 )
	cairo? ( x11-libs/cairo )
	gnomeprint? ( gnome-base/libgnomeprint )
	~app-text/docbook-xml-dtd-4.2
	app-text/docbook-xsl-stylesheets"

DEPEND="${RDEPEND}
	>=dev-util/intltool-0.21
	dev-util/pkgconfig"

G2CONF="${G2CONF}
	$(use_with cairo)
	$(use_enable gnome)
	$(use_with gnomeprint)
	$(use_with python)
	$(use_enable static)"

DOCS="AUTHORS ChangeLog KNOWN_BUGS NEWS README RELEASE-PROCESS THANKS TODO"

src_unpack() {
	unpack ${A}
	cd ${S}

	# Disable python -c 'import gtk' during compile to prevent using
	# X being involved (#31589)
	epatch ${FILESDIR}/0.94-disable_python_gtk_import.patch

	libtoolize --force --copy || die "Elibtoolize failed"
}