# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

# This is the "Special Edition" version
MY_PV="se"
MOD="SoulKeeperB"

DESCRIPTION="Medieval melee combat mod for Unreal Tournament 2004"
HOMEPAGE="http://thesoulkeeper.com/"
SRC_URI="mirror://filesnetwork/Unreal_Tournament_2004/Modifications/sk_${MY_PV}_completeinstallation.zip"

LICENSE="free-noncomm"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="primaryuri strip"

DEPEND=">=games-fps/ut2004-3369-r1
	app-arch/unzip"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/ut2004

src_unpack() {
	unpack ${A}
	cd "${S}"

	# The zipfiles contain backslashes, so cannot use "unpack".
	# Cannot die on failure.
	unzip The_SoulKeeper_Special_Edition.zip
	unzip ExtraFiles.zip -d "${MOD}"
	rm *.zip QUICK_INSTALLATION_GUIDE.txt
}

src_install() {
	insinto "${dir}"
	doins -r * || die "doins failed"

	games_make_wrapper ${PN} "ut2004 -mod=${MOD}"
	make_desktop_entry ${PN} "UT2004 - Soul Keeper" "ut2004.xpm"

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	einfo "Bloom and decals should be disabled in the Settings menu,"
	einfo "otherwise the game may crash or show a white screen."
	echo
}