mew-6.8_p20230203.ebuild

mew-6.8_p20230203.ebuild (text/plain), 1.08 KB, created by Teika kazura on 2023-02-08 12:16:04 UTC

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
NEED_EMACS=24

inherit elisp readme.gentoo-r1

COMMIT_ID=f96266240586898ea44256f6b24743a50e1113cb
DESCRIPTION="Great MIME mail reader for Emacs/XEmacs"
HOMEPAGE="https://www.mew.org/"
SRC_URI="https://github.com/kazu-yamamoto/Mew/archive/${COMMIT_ID}.tar.gz"
S="${WORKDIR}/Mew-${COMMIT_ID}"

LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE="ssl l10n_ja"
RESTRICT="test"

DEPEND="sys-libs/zlib"
RDEPEND="${DEPEND}
	ssl? ( net-misc/stunnel )"

SITEFILE="50${PN}-gentoo.el"

src_configure() {
	econf \
		--with-elispdir="${SITELISP}/${PN}" \
		--with-etcdir="${SITEETC}/${PN}"
}

src_compile() {
	emake
	use l10n_ja && emake jinfo
	rm -f info/*~				# remove spurious backup files
}

src_install() {
	emake DESTDIR="${D}" install
	use l10n_ja && emake DESTDIR="${D}" install-jinfo
	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	dodoc 00api 00changes* 00diff 00readme dot.*

	DOC_CONTENTS="Please refer to /usr/share/doc/${PF} for sample
		configuration files."
	readme.gentoo_create_doc
}