viber-18.2.0.2-r1.ebuild

viber-18.2.0.2-r1.ebuild (text/plain), 9.77 KB, created by Alexander Kurakin on 2023-01-25 02:15:23 UTC

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

MULTILIB_COMPAT=( abi_x86_64 )

inherit desktop multilib-build pax-utils unpacker xdg

DESCRIPTION="Free text and calls"
HOMEPAGE="https://www.viber.com"
SRC_URI="https://download.cdn.viber.com/cdn/desktop/Linux/${PN}.deb -> ${P}.deb"

QA_PREBUILT="opt/viber/Viber
	opt/viber/libexec/QtWebEngineProcess
	opt/viber/plugins/*/*.so*
	opt/viber/lib/*
	opt/viber/qml/*"

LICENSE="Viber-TOS"
SLOT="0"
KEYWORDS="-* ~amd64"
IUSE="+abi_x86_64 apulse +pulseaudio"
REQUIRED_USE="^^ ( apulse pulseaudio )"
RESTRICT="bindist mirror"

BDEPEND="sys-apps/fix-gnustack"
RDEPEND="app-arch/brotli[${MULTILIB_USEDEP}]
	app-arch/snappy[${MULTILIB_USEDEP}]
	app-arch/zstd[${MULTILIB_USEDEP}]
	app-crypt/mit-krb5[${MULTILIB_USEDEP}]
	dev-libs/expat[${MULTILIB_USEDEP}]
	dev-libs/glib:2[${MULTILIB_USEDEP}]
	dev-libs/libxml2[${MULTILIB_USEDEP}]
	dev-libs/libxslt[${MULTILIB_USEDEP}]
	dev-libs/nspr[${MULTILIB_USEDEP}]
	dev-libs/nss[${MULTILIB_USEDEP}]
	dev-libs/wayland[${MULTILIB_USEDEP}]
	media-libs/alsa-lib[${MULTILIB_USEDEP}]
	media-libs/fontconfig:1.0[${MULTILIB_USEDEP}]
	media-libs/freetype:2[${MULTILIB_USEDEP}]
	media-libs/gst-plugins-bad:1.0[${MULTILIB_USEDEP}]
	media-libs/gst-plugins-base:1.0[${MULTILIB_USEDEP}]
	media-libs/gstreamer:1.0[${MULTILIB_USEDEP}]
	media-libs/harfbuzz[${MULTILIB_USEDEP}]
	media-libs/lcms:2[${MULTILIB_USEDEP}]
	media-libs/libglvnd[${MULTILIB_USEDEP}]
	media-libs/libmng[${MULTILIB_USEDEP}]
	media-libs/libwebp[${MULTILIB_USEDEP}]
	media-libs/opus[${MULTILIB_USEDEP}]
	media-libs/tiff[${MULTILIB_USEDEP}]
	net-print/cups[${MULTILIB_USEDEP}]
	sys-apps/dbus[${MULTILIB_USEDEP}]
	sys-apps/systemd-utils[${MULTILIB_USEDEP}]
	sys-libs/mtdev
	sys-libs/zlib:0/1[${MULTILIB_USEDEP}]
	x11-libs/libdrm[${MULTILIB_USEDEP}]
	x11-libs/libICE[${MULTILIB_USEDEP}]
	x11-libs/libSM[${MULTILIB_USEDEP}]
	x11-libs/libX11[${MULTILIB_USEDEP}]
	x11-libs/libxcb:0/1.12[${MULTILIB_USEDEP}]
	x11-libs/libXext[${MULTILIB_USEDEP}]
	x11-libs/libXfixes[${MULTILIB_USEDEP}]
	x11-libs/libxkbcommon[${MULTILIB_USEDEP}]
	x11-libs/libxkbfile[${MULTILIB_USEDEP}]
	x11-libs/libXrandr[${MULTILIB_USEDEP}]
	x11-libs/libXScrnSaver[${MULTILIB_USEDEP}]
	x11-libs/libxshmfence[${MULTILIB_USEDEP}]
	x11-libs/libXtst[${MULTILIB_USEDEP}]
	x11-libs/tslib[${MULTILIB_USEDEP}]
	x11-libs/xcb-util-image[${MULTILIB_USEDEP}]
	x11-libs/xcb-util-keysyms[${MULTILIB_USEDEP}]
	x11-libs/xcb-util-renderutil[${MULTILIB_USEDEP}]
	x11-libs/xcb-util-wm[${MULTILIB_USEDEP}]
	apulse? ( media-sound/apulse[${MULTILIB_USEDEP}] )
	pulseaudio? ( media-libs/libpulse[${MULTILIB_USEDEP}] )"

S="${WORKDIR}"

src_prepare() {
	default

	pax-mark -m opt/viber/Viber \
			opt/viber/QtWebEngineProcess

	fix-gnustack -f opt/viber/lib/libQt6WebEngineCore.so.6 > /dev/null \
		|| die "removing execstack flag failed"

	if use apulse ; then
		sed -i '/Exec=/s|/opt|apulse /opt|' \
			usr/share/applications/viber.desktop || die "sed failed"
	fi

	# remove hardcoded path
	sed -i '/Icon/s|/usr/share/pixmaps/viber.png|viber|' \
		usr/share/applications/viber.desktop \
		|| die "sed failed for viber.desktop"
}

src_install() {
	newicon -s scalable usr/share/icons/hicolor/scalable/apps/Viber.svg \
		viber.svg
	for size in 16x16 24x24 32x32 48x48 64x64 96x96 128x128 256x256; do
		newicon -s "${size%%x*}" usr/share/viber/"${size}".png viber.png
	done
	dosym ../icons/hicolor/96x96/apps/viber.png \
		/usr/share/pixmaps/viber.png

	domenu usr/share/applications/viber.desktop

	insinto /opt/viber
	doins -r opt/viber/.

	fperms +x /opt/viber/Viber \
		/opt/viber/lib/libQt6Core.so.6 \
		/opt/viber/lib/libQt6DBus.so.6 \
		/opt/viber/lib/libQt6EglFSDeviceIntegration.so.6 \
		/opt/viber/lib/libQt6Gui.so.6 \
		/opt/viber/lib/libQt6LabsAnimation.so.6 \
		/opt/viber/lib/libQt6LabsFolderListModel.so.6 \
		/opt/viber/lib/libQt6LabsQmlModels.so.6 \
		/opt/viber/lib/libQt6LabsSettings.so.6 \
		/opt/viber/lib/libQt6LabsSharedImage.so.6 \
		/opt/viber/lib/libQt6LabsWavefrontMesh.so.6 \
		/opt/viber/lib/libQt6Multimedia.so.6 \
		/opt/viber/lib/libQt6MultimediaQuick.so.6 \
		/opt/viber/lib/libQt6Network.so.6 \
		/opt/viber/lib/libQt6OpenGL.so.6 \
		/opt/viber/lib/libQt6Positioning.so.6 \
		/opt/viber/lib/libQt6PrintSupport.so.6 \
		/opt/viber/lib/libQt6Qml.so.6 \
		/opt/viber/lib/libQt6QmlLocalStorage.so.6 \
		/opt/viber/lib/libQt6QmlModels.so.6 \
		/opt/viber/lib/libQt6QmlWorkerScript.so.6 \
		/opt/viber/lib/libQt6QmlXmlListModel.so.6 \
		/opt/viber/lib/libQt6Quick.so.6 \
		/opt/viber/lib/libQt6QuickControls2.so.6 \
		/opt/viber/lib/libQt6QuickControls2Impl.so.6 \
		/opt/viber/lib/libQt6QuickDialogs2.so.6 \
		/opt/viber/lib/libQt6QuickDialogs2QuickImpl.so.6 \
		/opt/viber/lib/libQt6QuickDialogs2Utils.so.6 \
		/opt/viber/lib/libQt6QuickLayouts.so.6 \
		/opt/viber/lib/libQt6QuickParticles.so.6 \
		/opt/viber/lib/libQt6QuickShapes.so.6 \
		/opt/viber/lib/libQt6QuickTemplates2.so.6 \
		/opt/viber/lib/libQt6Sql.so.6 \
		/opt/viber/lib/libQt6StateMachine.so.6 \
		/opt/viber/lib/libQt6StateMachineQml.so.6 \
		/opt/viber/lib/libQt6WaylandClient.so.6 \
		/opt/viber/lib/libQt6WaylandCompositor.so.6 \
		/opt/viber/lib/libQt6WaylandEglClientHwIntegration.so.6 \
		/opt/viber/lib/libQt6WaylandEglCompositorHwIntegration.so.6 \
		/opt/viber/lib/libQt6WebChannel.so.6 \
		/opt/viber/lib/libQt6WebEngineCore.so.6 \
		/opt/viber/lib/libQt6WebEngineQuick.so.6 \
		/opt/viber/lib/libQt6WebEngineQuickDelegatesQml.so.6 \
		/opt/viber/lib/libQt6WebSockets.so.6 \
		/opt/viber/lib/libQt6Widgets.so.6 \
		/opt/viber/lib/libQt6WlShellIntegration.so.6 \
		/opt/viber/lib/libQt6XcbQpa.so.6 \
		/opt/viber/lib/libXcomposite.so.1 \
		/opt/viber/lib/libXdamage.so.1 \
		/opt/viber/lib/libb2.so.1 \
		/opt/viber/lib/libcrypto.so.1.1 \
		/opt/viber/lib/libdouble-conversion.so.3 \
		/opt/viber/lib/libicudata.so.66 \
		/opt/viber/lib/libicui18n.so.66 \
		/opt/viber/lib/libicuuc.so.66 \
		/opt/viber/lib/libjpeg.so.8 \
		/opt/viber/lib/libminizip.so.1 \
		/opt/viber/lib/libpcre2-16.so.0 \
		/opt/viber/lib/libpng16.so.16 \
		/opt/viber/lib/libre2.so.5 \
		/opt/viber/lib/libssl.so.1.1 \
		/opt/viber/lib/libwebp.so.6 \
		/opt/viber/lib/libViberRTC.so \
		/opt/viber/lib/libqrencode.so \
		/opt/viber/libexec/QtWebEngineProcess \
		/opt/viber/plugins/{generic,imageformats,platforminputcontexts,platforms,printsupport,sqldrivers,tls,wayland-decoration-client,wayland-graphics-integration-client,wayland-graphics-integration-server,wayland-shell-integration,xcbglintegrations}/ \
		/opt/viber/qml/QtQuick/libqtquick2plugin.so \
		/opt/viber/qml/QtQuick/Dialogs/libqtquickdialogsplugin.so \
		/opt/viber/qml/QtQuick/Dialogs/quickimpl/libqtquickdialogs2quickimplplugin.so \
		/opt/viber/qml/QtQuick/LocalStorage/libqmllocalstorageplugin.so \
		/opt/viber/qml/QtQuick/Layouts/libqquicklayoutsplugin.so \
		/opt/viber/qml/QtQuick/tooling/libquicktoolingplugin.so \
		/opt/viber/qml/QtQuick/Templates/libqtquicktemplates2plugin.so \
		/opt/viber/qml/QtQuick/Controls/Universal/impl/libqtquickcontrols2universalstyleimplplugin.so \
		/opt/viber/qml/QtQuick/Controls/Universal/libqtquickcontrols2universalstyleplugin.so \
		/opt/viber/qml/QtQuick/Controls/impl/libqtquickcontrols2implplugin.so \
		/opt/viber/qml/QtQuick/Controls/Material/impl/libqtquickcontrols2materialstyleimplplugin.so \
		/opt/viber/qml/QtQuick/Controls/Material/libqtquickcontrols2materialstyleplugin.so \
		/opt/viber/qml/QtQuick/Controls/Fusion/impl/libqtquickcontrols2fusionstyleimplplugin.so \
		/opt/viber/qml/QtQuick/Controls/Fusion/libqtquickcontrols2fusionstyleplugin.so \
		/opt/viber/qml/QtQuick/Controls/Basic/impl/libqtquickcontrols2basicstyleimplplugin.so \
		/opt/viber/qml/QtQuick/Controls/Basic/libqtquickcontrols2basicstyleplugin.so \
		/opt/viber/qml/QtQuick/Controls/Imagine/impl/libqtquickcontrols2imaginestyleimplplugin.so \
		/opt/viber/qml/QtQuick/Controls/Imagine/libqtquickcontrols2imaginestyleplugin.so \
		/opt/viber/qml/QtQuick/Controls/libqtquickcontrols2plugin.so \
		/opt/viber/qml/QtQuick/Window/libquickwindowplugin.so \
		/opt/viber/qml/QtQuick/Shapes/libqmlshapesplugin.so \
		/opt/viber/qml/QtQuick/Particles/libparticlesplugin.so \
		/opt/viber/qml/QtQuick/NativeStyle/libqtquickcontrols2nativestyleplugin.so \
		/opt/viber/qml/Qt/labs/qmlmodels/liblabsmodelsplugin.so \
		/opt/viber/qml/Qt/labs/sharedimage/libsharedimageplugin.so \
		/opt/viber/qml/Qt/labs/folderlistmodel/libqmlfolderlistmodelplugin.so \
		/opt/viber/qml/Qt/labs/settings/libqmlsettingsplugin.so \
		/opt/viber/qml/Qt/labs/wavefrontmesh/libqmlwavefrontmeshplugin.so \
		/opt/viber/qml/Qt/labs/platform/libqtlabsplatformplugin.so \
		/opt/viber/qml/Qt/labs/animation/liblabsanimationplugin.so \
		/opt/viber/qml/QtWayland/Client/TextureSharing/libwaylandtexturesharingplugin.so \
		/opt/viber/qml/QtWayland/Compositor/XdgShell/libwaylandcompositorxdgshellplugin.so \
		/opt/viber/qml/QtWayland/Compositor/TextureSharingExtension/libwaylandtexturesharingextensionplugin.so \
		/opt/viber/qml/QtWayland/Compositor/IviApplication/libwaylandcompositoriviapplicationplugin.so \
		/opt/viber/qml/QtWayland/Compositor/libqwaylandcompositorplugin.so \
		/opt/viber/qml/QtWayland/Compositor/WlShell/libwaylandcompositorwlshellplugin.so \
		/opt/viber/qml/QtQml/WorkerScript/libworkerscriptplugin.so \
		/opt/viber/qml/QtQml/libqmlplugin.so \
		/opt/viber/qml/QtQml/XmlListModel/libqmlxmllistmodelplugin.so \
		/opt/viber/qml/QtQml/StateMachine/libqtqmlstatemachineplugin.so \
		/opt/viber/qml/QtQml/Models/libmodelsplugin.so \
		/opt/viber/qml/QtWebChannel/libwebchannelplugin.so \
		/opt/viber/qml/Qt5Compat/GraphicalEffects/private/libqtgraphicaleffectsprivateplugin.so \
		/opt/viber/qml/Qt5Compat/GraphicalEffects/libqtgraphicaleffectsplugin.so \
		/opt/viber/qml/QtWebEngine/ControlsDelegates/libqtwebenginequickdelegatesplugin.so \
		/opt/viber/qml/QtWebEngine/libqtwebenginequickplugin.so \
		/opt/viber/qml/QtMultimedia/libquickmultimediaplugin.so

	dosym ../../opt/viber/Viber /usr/bin/Viber
}