gnormalize-0.49.ebuild

gnormalize-0.49.ebuild (text/plain), 1.25 KB, created by Tristan Heaven (RETIRED) on 2006-04-10 13:16:15 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Gtk2-Perl front-end to various audio utilities"
HOMEPAGE="http://gnormalize.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="aac cdrom flac mp3 musepack normalize vorbis"

RDEPEND=">=dev-perl/gtk2-perl-1.062
	aac? ( >=media-libs/faac-1.24
		>=media-libs/faad2-2.0 )
	cdrom? ( >=dev-perl/CDDB_get-2.25
		>=media-sound/cdcd-0.6.6
		|| ( >=media-sound/cdparanoia-3.9.8
			>=app-cdr/cdrtools-2.01
			>=app-cdr/dvdrtools-0.1.6 ) )
	flac? ( >=media-libs/flac-1.1.1
		!vorbis? ( >=media-sound/flac123-0.0.8 ) )
	mp3? ( >=media-sound/lame-3.96.1
		>=dev-perl/MP3-Info-1.13
		|| ( >=media-sound/madplay-0.15.1b
			>=media-sound/mpg321-0.2.10
			>=media-sound/mpg123-0.59s ) )
	musepack? ( >=media-sound/musepack-tools-1.15u )
	normalize? ( >=media-sound/normalize-0.7.6 )
	vorbis? ( >=media-sound/vorbis-tools-1.0.1 )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	unpack ./${PN}.1.bz2
}

src_install() {
	dobin ${PN} || die "dobin failed"

	insinto /usr/share/${PN}
	doins -r animations

	doicon icons/${PN}.png
	make_desktop_entry ${PN}

	doman ${PN}.1
	dodoc README
}