# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit toolchain-funcs eutils games

DESCRIPTION="Team-based aliens vs humans FPS with buildable structures"
HOMEPAGE="http://tremulous.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.zip
	http://0day.icculus.org/mirrors/${PN}/${P}.zip
	ftp://ftp.wireplay.co.uk/pub/quake3arena/mods/${PN}/${P}.zip"

LICENSE="GPL-2
	CCPL-Attribution-ShareAlike-2.5"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated opengl"
RESTRICT="nomirror"

UIDEPEND="media-libs/alsa-lib
	media-libs/libsdl
	media-libs/openal
	virtual/opengl
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"
RDEPEND="opengl? ( ${UIDEPEND} )
	!dedicated? ( !opengl? ( ${UIDEPEND} ) )"
DEPEND="${RDEPEND}
	app-arch/unzip"

home=${WORKDIR}/${PN}
S=${home}/${P}-src
dir=${GAMES_DATADIR}/${PN}

src_unpack() {
	unpack ${P}.zip
	cd "${WORKDIR}/${PN}"
	tar -zxf "${P}-src.tar.gz"
}

src_compile() {
	buildit() { use $1 && echo 1 || echo 0 ; }
	emake \
		BUILD_SERVER=$(buildit dedicated) \
		BUILD_CLIENT=$(buildit opengl) \
		CC="$(tc-getCC)" \
		DEFAULT_BASEDIR="${GAMES_DATADIR}/${PN}" \
		DEFAULT_LIBDIR="${GAMES_LIBDIR}/${PN}" \
		|| die "emake failed"
}

src_install() {
	insinto "${dir}"
	doins -r "${home}"/{base,*.pdf} || die "doins -r failed"

	if use opengl || ! use dedicated ; then
		# Install client
		newgamesbin build/release-linux-${ARCH}/${PN}.${ARCH} ${PN} \
			|| die "newgamesbin client failed"
		doicon "${home}"/${PN}.xpm
		make_desktop_entry ${PN} "Tremulous" ${PN}.xpm
	fi
	if use dedicated ; then
		# Install server
		newgamesbin build/release-linux-${ARCH}/tremded.${ARCH} ${PN}-ded \
			|| die "newgamesbin ded failed"
	fi

	dodoc "${home}"/ChangeLog

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	einfo "Read http://tremulous.net/manual/"
	echo
}