# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator games

MY_PN="oolite"
MY_PV=$(replace_version_separator 2 '-')
MY_PV=${MY_PV/beta/dev}

DESCRIPTION="Elite space trading & warfare remake"
HOMEPAGE="http://oolite.aegidian.org/"
FILE="oolite-${MY_PV}.x86.tar.gz"
ADDON_URL="http://capnhack.com/hosting/oolite/Oolite"
SRC_URI="ftp://ftp.alioth.net/oolite/${FILE}
	http://download.berlios.de/oolite-linux/${FILE}
	mildsound? ( ${ADDON_URL}/extra/oosounds3.zip )
	kleptohud? ( http://oosat.alioth.net/files/active/0/kleptohud.oxp.zip )
	amigasound? ( ${ADDON_URL}/OXPs/E5Amigasoundpack01oxp.zip )"

# This particular licence isn't in Portage yet
LICENSE="CCPL-Attribution-NonCommercial-ShareAlike-2.0"

SLOT="0"
KEYWORDS="~amd64 ~x86"

# Many add-ons at http://capnhack.com/hosting/oolite/Oolite/OoSat.html
IUSE="amigasound kleptohud mildsound"

RDEPEND="virtual/opengl
	x86? (
		>=media-libs/libsdl-1.2.8-r1
		>=media-libs/sdl-gfx-2.0.13-r1
		>=media-libs/sdl-image-1.2.3-r1
		>=media-libs/sdl-mixer-1.2.6
		virtual/opengl
		|| (
			(
				media-libs/mesa
				x11-libs/libX11
				x11-libs/libXau
				x11-libs/libXdmcp
				x11-libs/libXext )
			virtual/x11 ) )
	amd64? (
		app-emulation/emul-linux-x86-libxml2
		app-emulation/emul-linux-x86-libxslt
		>=app-emulation/emul-linux-x86-sdl-2.3
		app-emulation/emul-linux-x86-xlibs )"
DEPEND="app-arch/unzip"

S=${WORKDIR}/oolite-installer
dir=${GAMES_PREFIX_OPT}/Oolite

src_install() {
	local oxp_dir=${D}/${dir}/AddOns

	sed -i install \
		-e "s:/usr/local:${D}opt:" \
		-e "s:\$INSTALLDIR/bin:${D}${GAMES_PREFIX_OPT}/\$TOPLEVEL/bin:" \
		-e "s:OOLITE_ROOT=\$INSTALLDIR:OOLITE_ROOT=${GAMES_PREFIX_OPT}:" \
		|| die "sed failed"

	dodir "${dir}"/bin
	./install systemwide || die "install failed"

	# Remove updater program
	rm "${D}/${dir}"/bin/oolite-update

	# Remove unnecessary libraries which revdep-rebuild would moan about
	rm -r "${D}/${dir}"/oolite-deps/GNUstep/System/Library/Bundles/{GSPrinting,SSL.bundle}

	# Add-on packs - http://wiki.alioth.net/index.php/OXP
	mkdir -p "${oxp_dir}"
	if use mildsound ; then
		# Install OXP pack
		cp -r "${WORKDIR}"/oosounds3/* "${oxp_dir}"/ \
			|| die "cp mildsound failed"
	fi
	if use amigasound ; then
		cd "${WORKDIR}"/E5Amigasoundpack01oxp
		mv readme.txt e5amigasoundpack.oxp/
		cd e5amigasoundpack.oxp/Music
		# The two files are identical, so replace one with a symlink
		ln -sf BlueDanube.ogg OoliteTheme.ogg || die "ln amigasound failed"
		cd "${S}"
		cp -r "${WORKDIR}"/E5Amigasoundpack01oxp/* "${oxp_dir}"/ \
			|| die "cp amigasound failed"
	fi
	if use kleptohud ; then
		# http://oosat.alioth.net/node/31
		cp -r "${WORKDIR}"/kleptohud.oxp/* "${oxp_dir}"/ \
			|| die "cp kleptohud failed"
	fi

	# Use wrapper for pre-compiled binary
	games_make_wrapper ${MY_PN} "${dir}"/bin/${MY_PN}
	make_desktop_entry ${MY_PN} "Oolite"

	prepgamesdirs
}