Proposed ebuild for quodlibet-0.19

quodlibet-0.19.ebuild (text/plain), 1.72 KB, created by Kai Huuhko on 2006-04-02 01:35:51 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils python

DESCRIPTION="Quod Libet is a new kind of audio player."
HOMEPAGE="http://www.sacredchao.net/quodlibet"
SRC_URI="http://www.sacredchao.net/~piman/software/${P}.tar.gz"
RESTRICT="nomirror"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="mad vorbis flac aac musepack alsa oss esd gnome"

RDEPEND=">=virtual/python-2.3
	>=dev-python/pygtk-2.8
	>=x11-libs/gtk+-2.8
	>=media-sound/mutagen-1.0
	>=media-libs/gstreamer-0.10.3
	>=media-libs/gst-plugins-base-0.10.3
	>=media-libs/gst-plugins-good-0.10.2
	>=dev-python/gst-python-0.10.2
	mad? ( >=media-plugins/gst-plugins-mad-0.10.2 )
	vorbis? ( dev-python/pyvorbis
		>=media-plugins/gst-plugins-vorbis-0.10.0
		>=media-plugins/gst-plugins-ogg-0.10.0 )
	x86? (
		flac? ( >=media-plugins/gst-plugins-flac-0.10.0
			=dev-python/ctypes-0.9.6 )
		aac? ( >=media-plugins/gst-plugins-faad-0.10.0
			=dev-python/ctypes-0.9.6 )
		musepack? ( >=media-plugins/gst-plugins-musepack-0.10.0
			>=media-libs/gst-plugins-bad-0.10.1
			=dev-python/ctypes-0.9.6 )
	)
	alsa? ( >=media-plugins/gst-plugins-alsa-0.10.0 )
	oss? ( >=media-plugins/gst-plugins-oss-0.10.0 )
	esd? ( >=media-plugins/gst-plugins-esd-0.10.0 )
	gnome? ( dev-python/gnome-python-extras
			>=media-plugins/gst-plugins-gnomevfs-0.10.0
			dev-python/feedparser )"

src_unpack() {
	unpack ${A}
	cd ${S}

	epatch ${FILESDIR}/quodlibet-0.17.1-multilibfix.patch
}

src_compile() {
	make extensions
}

src_install() {
	make PREFIX=/usr DESTDIR=${D} libdir=$(get_libdir) install
	dodoc README NEWS
}

pkg_postinst() {
	python_version
	python_mod_optimize /usr/share/${PN}
}

pkg_postrm() {
	python_mod_cleanup /usr/share/${PN}
}