# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="Team-based aliens vs humans FPS with buildable structures"
HOMEPAGE="http://tremulous.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.zip
	http://0day.icculus.org/mirrors/${PN}/${P}.zip
	ftp://ftp.wireplay.co.uk/pub/quake3arena/mods/${PN}/${P}.zip"

LICENSE="GPL-2
	CCPL-Attribution-ShareAlike-2.5"
SLOT="0"
KEYWORDS="~x86"
IUSE="dedicated sdl"
RESTRICT="nomirror"

UIDEPEND="media-libs/alsa-lib
	media-libs/libsdl
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"
# Both client and server are built - there's no choice
RDEPEND="${UIDEPEND}"
DEPEND="${RDEPEND}
	app-arch/unzip"

home=${WORKDIR}/${PN}
S=${home}/${P}-src
dir=${GAMES_DATADIR}/${PN}

src_unpack() {
	unpack ${P}.zip
	cd "${WORKDIR}/${PN}"
	tar -zxf "${P}-src.tar.gz"
}

src_install() {
	insinto "${dir}"
	doins -r "${home}"/{base,*.pdf} || die "doins -r failed"

	exeinto "${dir}"
	if use sdl || ! use dedicated ; then
		# Install client
		newexe build/release-linux-x86/${PN}.x86 ${PN} \
			|| die "newexe failed"
		doicon "${home}"/${PN}.xpm
		games_make_wrapper ${PN} ./${PN} "${dir}"
		make_desktop_entry ${PN} "Tremulous" ${PN}.xpm
	fi
	if use dedicated ; then
		# Install server
		newexe build/release-linux-x86/tremded.x86 ${PN}-ded \
			|| die "newexe ded failed"
		games_make_wrapper ${PN}-ded ./${PN}-ded "${dir}"
	fi

	dodoc "${home}"/ChangeLog

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	einfo "Read http://tremulous.net/manual/"
	echo
}