# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit cvs

ECVS_SERVER="cvs.sourceforge.net:/cvsroot/lcdproc"
ECVS_MODULE="lcdproc"
ECVS_USER="anonymous"

DESCRIPTION="Client/Server suite to drive all kinds of LCD (-like) devices"
HOMEPAGE="http://lcdproc.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc ncurses samba svga lirc xosd"

DEPEND=">=sys-apps/baselayout-1.6.4
	>=sys-apps/sed-4
	doc? ( >=app-text/docbook-sgml-utils-0.6.11-r2 )
	ncurses? ( >=sys-libs/ncurses-5.3 )
	svga? ( >=media-libs/svgalib-1.4.3 )
	xosd? ( >=x11-libs/xosd-2.2.8 )"

S=${WORKDIR}/${ECVS_MODULE}

pkg_setup() {
        ewarn ""
        ewarn "The hd44780-driver didn't compile with my"
        ewarn "linux-headers-2.6.11-r3 so I dropped it in this"
        ewarn "ebuild. Sorry to all the people who need it,"
        ewarn "you're welcome to fix the problem yourself.\n"
	ewarn ""
	ewarn "Check the configure-output for missing optional"
	ewarn "libs that you don't have installed, some drivers"
	ewarn "may not be built\n"
}

src_compile() {

	# By default, all drivers that are supported by the given plattform/hardware
	# are compiled (of course respecting the existing USE flags). If the
	# LCDPROC_DRIVERS environment variable is set to a comma separated list, only
	# the specified drivers will be compiled.
	# Example:
	#
	#   env LCDPROC_DRIVERS="curses,CFontz" emerge lcdproc
	#
	# NOTE: The ebuild still respects your USE variable and will not install any
	# additional packages unless the corresponding USE flag is set!
	# You might have to alter it if e.g. ncurses is normally not part of your
	# USE variable.
	# Example:
	#
	#   env USE="$USE ncurses" LCDPROC_DRIVERS="curses,CFontz" emerge lcdproc

	local myconf

	myconf="--enable-drivers=bayrad,CFontz,CFontz633,CFontzPacket,CwLnx,"
#	myconf="${myconf}glcdlib,glk,hd44780,icp_a106,imon,IOWarrior,irman,"
	myconf="${myconf}glcdlib,glk,icp_a106,imon,IOWarrior,irman,"
	myconf="${myconf}joy,lb216,lcdm001,lcterm,ms6931,mtc_s16209x,"
	myconf="${myconf}MtxOrb,NoritakeVFD,pylcd,sed1330,sed1520,serialVFD,"
	myconf="${myconf}sli,stv5730,t6963,text,tyan,ula200"

	use ncurses && myconf="${myconf},curses"
	use svga && myconf="${myconf},svga"
	use lirc && myconf="${myconf},lirc"
	use xosd && myconf="${myconf},xosd"

	[ x"${LCDPROC_DRIVERS}" = x ] || \
		myconf="--enable-drivers=${LCDPROC_DRIVERS}"

	use samba && myconf="${myconf} --enable-stat-smbfs"
	myconf="${myconf} --enable-stat-nfs"

	sh autogen.sh || die "autogen.sh failed"

	econf ${myconf} || die
	emake || die

	if use doc; then
		cd ${S}/docs/lcdproc-user
		docbook2html lcdproc-user.docbook
	fi
}

src_install() {
	dosbin server/LCDd
	dobin clients/lcdproc/lcdproc

	doman docs/lcdproc.1 docs/LCDd.8

	dodoc README ChangeLog INSTALL

	if use doc; then
		insinto /usr/share/doc/${PF}/lcdproc-user
		doins docs/lcdproc-user/*.html
	fi

	docinto olddocs
	dodoc docs/README.dg* docs/*.txt

	insinto /usr/share/doc/${PF}/clients/examples
	doins clients/examples/*.pl
	insinto /usr/share/doc/${PF}/clients/headlines
	doins clients/headlines/lcdheadlines

	insinto /etc
	doins LCDd.conf
	doins scripts/lcdproc.conf

	insinto /usr/share/lcdproc/drivers
	doins server/drivers/*.o
        doins server/drivers/*.so
        doins server/drivers/*.a
        doins server/drivers/*.txt

	exeinto /etc/init.d
	doexe ${FILESDIR}/LCDd
	doexe ${FILESDIR}/lcdproc
}

pkg_postinst() {
	ewarn ""
	ewarn "The hd44780-driver didn't compile with my"
	ewarn "linux-headers-2.6.11-r3 so I dropped it in this"
	ewarn "ebuild. Sorry to all the people who need it,"
	ewarn "you're welcome to fix the problem yourself.\n"
	einfo ""
	einfo "Your drivers are in /usr/share/lcdproc/drivers,"
	einfo "please tell LCDd in /etc/LCDd.conf\n"
}