# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit wxwidgets eutils flag-o-matic

IUSE="encode mad"

MY_P="${PN}-src-1.3.0b"
DESCRIPTION="Free crossplatform audio editor"
HOMEPAGE="http://audacity.sourceforge.net/"
SRC_URI="mirror://sourceforge/audacity/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

DEPEND="=x11-libs/wxGTK-2.6*
	>=app-arch/zip-2.3
	media-libs/libid3tag
	>=media-libs/libsndfile-1.0.0
	>=media-libs/libvorbis-1.0
	encode? ( >=media-sound/lame-3.92 )
	mad? ( >=media-libs/libmad-0.14.2b )"

WX_GTK_VER="2.6"

S="${WORKDIR}/${MY_P}-beta"

src_compile() {
	if built_with_use '=x11-libs/wxGTK-2.6*' gtk2 ; then
		need-wxwidgets gtk2
	else
		need-wxwidgets gtk
	fi

	filter-flags -fPIC

	econf \
		$(use_with mad libmad system) \
		--with-vorbis=system \
		--with-id3tag=system \
		--with-libsndfile=system || die

	# parallel borks
	emake -j1 || die
}

src_install() {
	make DESTDIR="${D}" install || die

	# Remove bad doc install
	rm -rf ${D}/usr/share/doc

	# Install our docs

	insinto /usr/share/icons/hicolor/48x48/apps
	newins images/AudacityLogo48x48.xpm audacity.xpm

	make_desktop_entry audacity Audacity audacity
}