sdl-sge-030809.ebuild

sdl-sge-030809.ebuild (text/plain), 1.86 KB, created by Tristan Heaven (RETIRED) on 2006-03-18 02:58:13 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils
MY_P="sge${PV}"

DESCRIPTION="Graphics extensions library for SDL"
HOMEPAGE="http://www.etek.chalmers.se/~e8cal1/sge/"
SRC_URI="${HOMEPAGE}files/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc examples image truetype"

RDEPEND=">=media-libs/libsdl-1.2
		image? ( >=media-libs/sdl-image-1.2 )
		truetype? ( >=media-libs/freetype-2 )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	use image && USE_IMG=y \
		|| USE_IMG=n
	use truetype && USE_FT=y \
		|| USE_FT=n
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${P}-freetype.patch"
	#epatch "${FILESDIR}/${P}-cmap.patch"
}

src_compile() {
	emake \
		"USE_IMG=${USE_IMG}" \
		"USE_FT=${USE_FT}" \
		"CFLAGS=${CXXFLAGS} \$(SGE_CFLAGS) \$(FT_CFLAGS) -fPIC" \
		|| die "emake failed"

	if use examples ; then
		einfo "Compiling examples"
		cd examples
		MAKEOPTS="-j1" # FIXME
		emake \
			"USE_IMG=${USE_IMG}" \
			"USE_FT=${USE_FT}" \
			"CFLAGS=${CXXFLAGS} \$(SGE_CFLAGS) \$(FT_CFLAGS) -I./../" \
			|| die "emake (examples) failed"
	fi
}

src_install() {
	make install \
		"PREFIX=${D}/usr" \
		"PREFIX_H=${D}/usr/include/SDL" \
		|| die "make install failed"

	dodoc README Todo WhatsNew

	use doc && dohtml docs/*

	if use examples ; then
		insinto "${ROOT}/usr/share/doc/${PF}"
		exeinto "${ROOT}/usr/share/doc/${PF}/examples/bin"
		doins -r examples
		cd "${D}/usr/share/doc/${PF}/examples"
		mkdir src

		if use truetype ; then
			mv font.ttf bin
			mv basics_c.c src
		else
			rm {basics,blitting,input,alpha,inputdeluxe}.cpp
			rm basics_c.c
			rm font.ttf ttf_readme
		fi

		if use image ; then
			mv sfont.png bin
			mv sfont.cpp src
		else
			rm sfont.*
		fi

		mv *.bmp bin
		mv *.cpp src
		rm Makefile

		for o in *.o ; do
			doexe ${o%.o}
			rm ${o%.o} ${o}
		done
	fi
}