# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit linux-mod

DESCRIPTION="Drivers for Sirrix AG's PCI4S0 4-port BRI card"
HOMEPAGE="http://www.sirrix.de/content/pages/pci4s0en.htm"
SRC_URI="http://www.sirrix.de/download/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="net-misc/asterisk"
RDEPEND=""

CONTAINER_S=${WORKDIR}/${PN}
S=${CONTAINER_S}/sirrix-pci

ESNACC_PN=esnacc
ESNACC_PV=050427
ESNACC_S=${CONTAINER_S}/SNACC
ESNACC_PREFIX=${ESNACC_S}/usr

BUILD_TARGETS="modules"
BUILD_PARAMS="ESNACC_PREFIX=${ESNACC_PREFIX} KVER=${KV_FULL}"
MODULE_NAMES="sirrix_pfic(misc:${S}/pfic:${S}/pfic)
			  sirrix_bch(misc:${S}/bchdev:${S}/bchdev)
			  sirrix_dch(misc:${S}/dchdev:${S}/dchdev)
			  sirrix_base(misc:${S}/layer1:${S}/layer1)"

src_unpack() {
	unpack ${A}
	cd ${CONTAINER_S}

	tar -xzf ${ESNACC_PN}-${ESNACC_PV}.tgz
	tar -xzf sirrix-pci-release-${PV}.tgz

	cp ${S}/udev/sirrix.rules ${S}/udev/60-sirrix.rules
	cp ${S}/udev/sirrix.permissions ${S}/udev/60-sirrix.permissions
}

src_compile() {
	cd ${ESNACC_S}
	econf || die
	make prefix=${ESNACC_PREFIX} install || die

	linux-mod_src_compile
}

src_install() {
	linux-mod_src_install

	dodir /dev/sirrix
	fowners asterisk:asterisk  /dev/sirrix

	insinto /etc/udev/rules.d
	doins ${S}/udev/60-sirrix.rules ${S}/udev/60-sirrix.permissions
}