# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/kopete/kopete-0.12_alpha1-r1.ebuild,v 1.1 2006/03/05 22:00:38 flameeyes Exp $

inherit kde eutils

MY_P="${P/_/-}"

DESCRIPTION="KDE multi-protocol IM client"
HOMEPAGE="http://kopete.kde.org/"
LICENSE="GPL-2"

KEYWORDS="~amd64 ~x86"
IUSE="sametime ssl xmms xscreensaver nolatexplugin noautoreplaceplugin
nohistoryplugin nocontactnotesplugin nocryptographyplugin
noconnectionstatusplugin notranslatorplugin nonowlisteningplugin
nowebpresenceplugin notexteffectplugin nohighlightplugin noaliasplugin
nonetmeetingplugin noaddbookmarksplugin nostatisticsplugin notestbedprotocol
nogroupwiseprotocol nomsnprotocol noircprotocol nooscarprotocol noyahooprotocol
nowinpopupprotocol nosmsprotocol nojabberprotocol nogaduprotocol
nomeanwhileprotocol"

SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

S="${WORKDIR}/${MY_P}"

# The kernel_linux? ( ) conditional dependencies are for webcams, not supported
# on other kernels AFAIK
BOTH_DEPEND="dev-libs/libxslt
	dev-libs/libxml2
	net-dns/libidn
	>=dev-libs/glib-2
	app-crypt/qca
	sametime? ( =net-libs/meanwhile-0.4* )
	xmms? ( media-sound/xmms )
	|| ( (
		x11-libs/libX11
		x11-libs/libXext
		x11-libs/libXrender
		xscreensaver? ( x11-libs/libXScrnSaver )
		) virtual/x11 )
	kernel_linux? ( virtual/opengl )"

RDEPEND="${BOTH_DEPEND}
	ssl? ( app-crypt/qca-tls )
	!kde-base/kopete"

DEPEND="${BOTH_DEPEND}
	kernel_linux? ( virtual/os-headers )
	|| ( (
			x11-proto/videoproto
			x11-proto/xextproto
			x11-proto/xproto
			kernel_linux? ( x11-libs/libXv )
			xscreensaver? ( x11-proto/scrnsaverproto )
		) virtual/x11 )"

need-kde 3.4

disable_plugin() {
	einfo "Disabling $PLUGIN plugin"
	sed "s/$PLUGIN//" ${S}/kopete/plugins/Makefile.am >${S}/kopete/plugins/Makefile.am.tmp
	mv ${S}/kopete/plugins/Makefile.am.tmp ${S}/kopete/plugins/Makefile.am
}

disable_protocol() {
	einfo "Disabling $PROTOCOL protocol"
	sed "s/$PROTOCOL//" ${S}/kopete/protocols/Makefile.am >${S}/kopete/protocols/Makefile.am.tmp
	mv ${S}/kopete/protocols/Makefile.am.tmp ${S}/kopete/protocols/Makefile.am
}

src_unpack() {
	kde_src_unpack
	epatch "${FILESDIR}/${P}-xscreensaver.patch"
	epatch "${FILESDIR}/${PN}-3.5.x-msn-filetransfer.patch"

	use nolatexplugin && PLUGIN="latex" && disable_plugin
	use noautoreplaceplugin && PLUGIN="autoreplace" && disable_plugin
	use nohistoryplugin && PLUGIN="history" && disable_plugin
	use nocontactnotesplugin && PLUGIN="contactnotes" && disable_plugin
	use nocryptographyplugin && PLUGIN="cryptography" && disable_plugin
	use noconnectionstatusplugin && PLUGIN="connectionstatus" && disable_plugin
	use notranslatorplugin && PLUGIN="translator" && disable_plugin
	use nonowlisteningplugin && PLUGIN="nowlistening" && disable_plugin
	use nowebpresenceplugin && PLUGIN="webpresence" && disable_plugin
	use notexteffectplugin && PLUGIN="texteffect" && disable_plugin
	use nohighlightplugin && PLUGIN="highlight" && disable_plugin
	use noaliasplugin && PLUGIN="alias" && disable_plugin
	use nonetmeetingplugin && PLUGIN="netmeeting" && disable_plugin
	use noaddbookmarksplugin && PLUGIN="addbookmarks" && disable_plugin
	use nostatisticsplugin && PLUGIN="statistics" && disable_plugin

	use notestbedprotocol && PROTOCOL="\$(TESTBED)" && disable_protocol
	use nogroupwiseprotocol && PROTOCOL="groupwise" && disable_protocol
	use nomsnprotocol && PROTOCOL="msn" && disable_protocol
	use noircprotocol && PROTOCOL="irc" && disable_protocol
	use nooscarprotocol && PROTOCOL="oscar" && disable_protocol
	use noyahooprotocol && PROTOCOL="yahoo" && disable_protocol
	use nowinpopupprotocol && PROTOCOL="winpopup" && disable_protocol
	use nosmsprotocol && PROTOCOL="\$(SMS)" && disable_protocol
	use nojabberprotocol && PROTOCOL="\$(JABBER)" && disable_protocol
	use nogaduprotocol && PROTOCOL="\$(GADU)" && disable_protocol
	use nomeanwhileprotocol && PROTOCOL="\$(MEANWHILE)" && disable_protocol

	rm -f ${S}/kopete/plugins/Makefile.in
	rm -f ${S}/kopete/protocols/Makefile.in
	rm -f ${S}/configure
}

src_compile() {
	# External libgadu support - doesn't work, kopete requires a specific development snapshot of libgadu.
	# Maybe we can enable it in the future.
	# The nowlistening plugin has xmms support.
	local myconf="$(use_enable sametime sametime-plugin)
	              $(use_with xmms) --without-external-libgadu
	              $(use_with xscreensaver)"

	kde_src_compile
}