media-sound/audacity-1.3.0b.ebuild

audacity-1.3.0b.ebuild (text/plain), 1.29 KB, created by Andrew D. Keyser (aka Legoguy) on 2006-03-10 15:18:02 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit wxwidgets eutils flag-o-matic

IUSE="encode mad vorbis"

MY_P="${PN}-src-${PV}"
DESCRIPTION="Free crossplatform audio editor"
HOMEPAGE="http://audacity.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"

DEPEND="=x11-libs/wxGTK-2.6*
	>=app-arch/zip-2.3
	media-libs/libid3tag
	>=media-libs/libsndfile-1.0.0
	vorbis? ( >=media-libs/libvorbis-1.0 )
	encode? ( >=media-sound/lame-3.92 )
	mad? ( >=media-libs/libmad-0.14.2b )"

WX_GTK_VER="2.6"

S="${WORKDIR}/${MY_P}-beta"

src_compile() {
	if built_with_use '=x11-libs/wxGTK-2.6*' gtk2 ; then
		need-wxwidgets gtk2
	else
		need-wxwidgets gtk
	fi

	filter-flags -fPIC

	econf \
		$(use_with mad libmad system) \
		$(use_with vorbis vorbis system) \
		--with-id3tag=system \
		--with-libsndfile=system || die

	# parallel borks
	emake -j1 || die
}

src_install() {
	make DESTDIR="${D}" install || die

	# Remove bad doc install
	rm -rf ${D}/usr/share/doc

	# Install our docs
	dodoc README.txt audacity-1.3-help.htb

	insinto /usr/share/icons/hicolor/48x48/apps
	newins images/AudacityLogo48x48.xpm audacity.xpm

	make_desktop_entry audacity Audacity audacity
}