# Copyright 2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit cvs

DESCRIPTION="Portable and multi-interface IRC client."
HOMEPAGE="http://weechat.flashtux.org/"
SRC_URI=""
LICENSE="GPL-2"

ECVS_SERVER="cvs.savannah.nongnu.org:/sources/weechat"
ECVS_MODULE="weechat"

S="${WORKDIR}/${ECVS_MODULE}"

SLOT="0"
KEYWORDS="~x86 ~amd64 ~ppc ~sparc"
IUSE="debug lua perl python ruby ssl"

DEPEND="automake
	autoconf
	sys-libs/ncurses
	perl? ( dev-lang/perl )
	python? ( virtual/python )
	ruby? ( dev-lang/ruby )
	lua? ( dev-lang/lua )
	ssl? ( net-libs/gnutls )"

# the stupid gettextize script prevents non-interactive mode, so we hax it
gettext_modify() {
	cp $(which gettextize) "${T}"/ || die "could not copy gettextize"
	sed -i \
		-e 's:read dummy < /dev/tty::' \
		"${T}"/gettextize
}


src_compile() {
	gettext_modify
	env \
		PATH="${T}:${PATH}" \
		NOCONFIGURE=yes \
		./autogen.sh
	econf \
		--enable-curses \
		$(use_enable perl) \
		$(use_enable python) \
		$(use_enable ruby) \
		$(use_enable lua) \
		$(use_enable ssl gnutls) \
		$(use_with debug debug 2) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS BUGS ChangeLog FAQ NEWS README TODO || die "dodoc failed"
}