Ebuild for syslog-ng-1.9.9

syslog-ng-1.9.9.ebuild (text/plain), 1.75 KB, created by Wolfram Schlich (RETIRED) on 2006-03-03 00:18:36 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit fixheadtails

DESCRIPTION="syslog replacement with advanced filtering features"
HOMEPAGE="http://www.balabit.com/products/syslog_ng/"
SRC_URI="http://www.balabit.com/downloads/syslog-ng/${PV%.*}/src/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 mips ppc ppc64 s390 sh sparc x86"
IUSE="hardened selinux static"

DEPEND="
	>=sys-apps/portage-2.0.51
	>=dev-libs/glib-2.0*
	dev-libs/eventlog
	sys-devel/flex"
PROVIDE="virtual/logger"

src_unpack() {
	unpack ${A}
	cd "${S}"
	ht_fix_file configure
	cd "${S}/doc/reference"
	tar xzf syslog-ng.html.tar.gz || die "tar failed"
}

src_compile() {
	local myconf="--disable-dependency-tracking --sysconfdir=/etc/syslog-ng"
	if useq static; then
		myconf="${myconf} --enable-static-linking"
	else
		myconf="${myconf} --enable-dynamic-linking"
	fi
	econf ${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"

	prepallman

	dodoc AUTHORS ChangeLog NEWS README \
		doc/examples/syslog-ng.conf.sample \
		doc/reference/{syslog-ng.xml,syslog-ng.xsl,syslog-ng.txt} \
		contrib/{syslog2ng,syslog-ng.vim,relogger.pl} \
		"${FILESDIR}/syslog-ng.conf."*
	dohtml doc/sgml/syslog-ng.html/*

	# Install default configuration
	insinto /etc/syslog-ng
	if use hardened || use selinux ; then
		newins "${FILESDIR}/syslog-ng.conf.gentoo.hardened" syslog-ng.conf
	else
		newins "${FILESDIR}/syslog-ng.conf.gentoo" syslog-ng.conf
	fi

	# Install snippet for logrotate, which may or may not be installed
	insinto /etc/logrotate.d
	newins "${FILESDIR}/syslog-ng.logrotate" syslog-ng

	newinitd "${FILESDIR}/syslog-ng.rc6" syslog-ng
}