keytouch-2.1.0.ebuild

keytouch-2.1.0.ebuild (text/plain), 1.77 KB, created by Tristan Heaven (RETIRED) on 2006-02-28 09:23:40 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils linux-info versionator

DESCRIPTION="Easily configure extra keyboard function keys"
HOMEPAGE="http://keytouch.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="kde"

RDEPEND=">=x11-libs/gtk+-2
		x11-misc/xbindkeys
		kde? ( || (
			kde-base/kdesu
			kde-base/kdebase ) )
		!kde? ( x11-libs/gksu )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Prevent sandbox violations
	sed -i 's/install-data-local//' \
		keytouchd/Makefile.in \
		keytouch-init/Makefile.in \
		keytouch-acpid/Makefile.in \
		|| die "sed failed"
}

src_compile() {
	for d in . keytouch-config keytouch-keyboard ; do
		cd "${S}/${d}"
		econf || die "econf ${d} failed"
		emake || die "emake ${d} failed"
	done
}

src_install() {
	doinitd "${FILESDIR}/keytouch"

	dodoc AUTHORS ChangeLog

	for d in . keytouch-config keytouch-keyboard ; do
		cd "${S}/${d}"
		make install DESTDIR="${D}" \
			|| die "make install ${d} failed"
	done

	cd "${S}/keytouch-config/pixmaps"
	make_desktop_entry keytouch keyTouch keyTouch.png System
	newicon icon.png keyTouch.png
}

pkg_postinst() {
	if [[ ${KV_MINOR} -ne 6 ]] ; then
		echo
		ewarn "Linux 2.6 is required to use this version"
		ewarn "of ${PN}."
		echo
	else
		echo
		einfo "To make this work, add \"keytouchd &\" to your"
		einfo "X startup programs and run"
		einfo "\"rc-update add keytouch default\""
		echo
		einfo "If support for your keyboard is not included in"
		einfo "this release, check for new keyboard files at"
		einfo "http://keytouch.sourceforge.net/dl-keyboards.html"
		echo
		einfo "x11-misc/keytouch-editor can be used to create"
		einfo "your own keyboard files."
		echo
	fi
}