ipw3945 kernel module

ipw3945-0.0.69.ebuild (text/plain), 1.92 KB, created by Vince C. on 2006-02-26 10:55:01 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# Author: VinzC ([e-mail])

inherit linux-mod

# The following works with both pre-releases and releases
S=${WORKDIR}/${P}

IEEE80211_VERSION="1.1.11"
FW_VERSION="1.13"
IPWD_VERSION="0.7.16"

DESCRIPTION="Intel(R) PRO/Wireless 3945 Network Connection driver for Linux"
HOMEPAGE="http://ipw3945.sourceforge.net"
SRC_URI="http://osdn.dl.sourceforge.net/sourceforge/${PN}/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

IUSE=""
DEPEND=">=net-wireless/ieee80211-${IEEE80211_VERSION}"
RDEPEND="${DEPEND}
		=net-wireless/ipw3945d-${IPWD_VERSION}
		=net-wireless/ipw3945-firmware-${FW_VERSION}
		net-wireless/wireless-tools"

BUILD_TARGETS="all"
MODULE_NAMES="ipw3945(net/wireless:)"
MODULESD_IPW3945_DOCS="README.ipw3945"

CONFIG_CHECK="NET_RADIO FW_LOADER"
ERROR_NET_RADIO="${P} requires support for Wireless LAN drivers (non-hamradio) & Wireless Extensions (CONFIG_NET_RADIO)."
ERROR_FW_LOADER="${P} requires Hotplug firmware loading support (CONFIG_FW_LOADER)."

pkg_setup() {
	linux-mod_pkg_setup

	if kernel_is 2 4; then
		die "${P} does not support building against kernel 2.4.x"
	fi

	BUILD_PARAMS="KSRC=${KV_DIR} KSRC_OUTPUT=${KV_OUT_DIR} IEEE80211_INC=/usr/include"
}

src_compile() {
	einfo
	einfo "You may safely ignore any errors from compilation that contain"
	einfo "warnings about undefined references to the ieee80211 subsystem."
	einfo

	linux-mod_src_compile
}

src_install() {
	linux-mod_src_install

	dodoc CHANGES ISSUES
}

pkg_postinst() {
	linux-mod_pkg_postinst

	if [ -f /lib/modules/${KV_FULL}/net/${PN}.ko ]; then
		einfo
		einfo "Modules from an earlier installation detected. You will need to manually"
		einfo "remove those modules by running the following commands:"
		einfo "  # rm -f /lib/modules/${KV_FULL}/net/${PN}.ko"
		einfo "  # rm -f /lib/modules/${KV_FULL}/net/ieee80211*.ko"
		einfo "  # depmod -a"
		einfo
	fi
}