# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit multilib

MY_P="${P}DrCox"

DESCRIPTION="XMMS2 is a redesign of the XMMS music player."
HOMEPAGE="http://wiki.xmms2.xmms.se/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="aac alsa curl ecore flac gnome jack modplug mp3 musepack python oss ruby samba sid speex vorbis"

RDEPEND=">=dev-libs/glib-2.6.0
	>=dev-db/sqlite-3.2.6
	aac? ( >=media-libs/faad2-2.0 )
	alsa? ( media-libs/alsa-lib )
	curl? ( >=net-misc/curl-7.11.2 )
	ecore? ( x11-libs/ecore )
	flac? ( media-libs/flac )
	gnome? ( gnome-base/gnome-vfs )
	jack? ( >=media-sound/jack-0.100.0 )
	modplug? ( media-libs/libmodplug )
	mp3? ( media-sound/madplay )
	musepack? ( media-libs/libmpcdec )
	python? ( >=dev-lang/python-2.2.1 >=dev-python/pyrex-0.9.3 )
	ruby? ( >=dev-lang/ruby-1.8 )
	samba? ( net-fs/samba )
	sid? ( media-sound/sidplay media-libs/resid )
	speex? ( media-libs/speex )
	vorbis? ( media-libs/libvorbis )"
DEPEND="${RDEPEND}
	>=dev-lang/python-2.2.1
	>=dev-util/scons-0.96"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e "s:/lib:/$(get_libdir):g" \
		SConstruct xmms2.pc.in xmmsenv.py
}

src_compile() {
	local u o MY_EXCLUDE=""
	for u in aac alsa curl ecore gnome:gnomevfs modplug flac jack mp3:mad \
	         musepack oss ruby samba sid speex vorbis ; do
		o=${u##*:} ; o=${o:-${u}}
		u=${u%%:*}
		use ${u} || MY_EXCLUDE="${MY_EXCLUDE} ${o}"
	done

	scons CCFLAGS="${CFLAGS}" CONFIG=1 EXCLUDE="${MY_EXCLUDE}" || die "scons failed"
}

src_install() {
	scons \
		PREFIX=/usr \
		MANDIR=/usr/share/man \
		INSTALLDIR="${D}" install \
		|| die "scons install failed"
	dodoc AUTHORS ChangeLog README
}