# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils qt3

DESCRIPTION="Utility for uploading photos to a Zoto account"
HOMEPAGE="http://www.zoto.com/"
SRC_URI="http://www.zoto.com/downloads/linux/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc debug exif"

RDEPEND="$(qt_min_version 3.3)
		exif? ( >=media-libs/libexif-0.6.12 )
		net-misc/curl
		>=dev-libs/xmlrpc-c-1.2
		media-libs/libpng
		media-libs/jpeg
		media-libs/libmng
		net-libs/gnutls
		dev-libs/expat
		media-libs/fontconfig"
DEPEND="${RDEPEND}
		doc? ( app-doc/doxygen )"

pkg_setup() {
	myconf="qt warn_on exceptions tagging thread"

	use debug && myconf="${myconf} debug tracing" \
		|| myconf="${myconf} release"
	use exif && myconf="${myconf} exif"
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i -e "/^CONFIG/c CONFIG += ${myconf}" \
		common/global_qmake_config \
		|| die "sed failed"
}

src_compile() {
	"${QTDIR}/bin/qmake" \
		"QMAKE=${QTDIR}/bin/qmake" \
		"LIBS+=-lcurl" \
		zulu.pro || die "qmake failed"

	emake || die "emake failed"

	if use doc ; then
		cd zulu-lib
		doxygen .doxy-conf
	fi
}

src_install() {
	dobin zulu-gui/zulu zulu-cli/zulu-cli \
		|| die "dobin failed"

	make_desktop_entry zulu "Zoto Uploader"

	use doc && dohtml -r zulu-lib/docs/html/
}