serverstats-0.8.ebuild

serverstats-0.8.ebuild (text/plain), 1.18 KB, created by David Danier on 2006-02-19 07:54:21 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit webapp depend.php

DESCRIPTION="serverstats is a rrdtool harvester and a lightweight replacement for cacti"
HOMEPAGE="http://serverstats.berlios.de/"
SRC_URI="http://download.berlios.de/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~x86"
IUSE=""

RDEPEND=">=net-analyzer/rrdtool-1.2
	virtual/cron"

need_php5

src_unpack() {
	unpack "${A}"
	cd "${S}"
	mv config.sample/ config/
}

src_install() {
	webapp_src_preinst

	einfo "Installing docs"
	dodoc doc/*.txt
	docinto examples
	newdoc sources/traffic/iptables.sample iptables-rules.sample
	newdoc sources/traffic/traffic.sh traffic.sh.sample
	rm sources/traffic/iptables.sample
	rm sources/traffic/traffic.sh
	touch sources/traffic/.keep
	rm -rf doc/
	rm -f INSTALL LICENSE sources/external/cacti/README

	einfo "Installing main files"
	cp -pPR . "${D}/${MY_HTDOCSDIR}"

	webapp_serverowned "${MY_HTDOCSDIR}"/graph

	cd "${D}/${MY_HTDOCSDIR}"
	local CONFFILE
	for CONFFILE in config/* ; do
	    webapp_configfile "${MY_HTDOCSDIR}/${CONFFILE}"
	done

	webapp_postinst_txt en ${FILESDIR}/postinstall-en.txt

	webapp_src_install
}