# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PN="alienarena"
RUN_FILE="alienarena-2006ge-x86.run"
DATA_FILE="alienarena-2006ge-data.tar.bz2"

DESCRIPTION="The ultimate freeware deathmatch game!"
HOMEPAGE="http://red.planetarena.org/"

COR_URL="http://cor.planetquake.gamespy.com/codered/files"
SRC_URI="${COR_URL}/${RUN_FILE}
	${COR_URL}/midniteskins.zip
	http://www.forsakenweb.com/battlescar.zip"

LICENSE="GPL-2"
SLOT="0"

# Should work on amd64 also
KEYWORDS="~x86"

IUSE="sdl"
RESTRICT="nomirror nostrip"

RDEPEND="sdl? ( >=dev-libs/DirectFB-0.9.22 >=media-libs/libsdl-1.2.8-r1 )
	amd64? ( app-emulation/emul-linux-x86-xlibs )
	virtual/opengl
	|| (
		(
			media-libs/mesa
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext
			x11-libs/libXxf86dga
			x11-libs/libXxf86vm )
		virtual/x11 )"
DEPEND="app-arch/unzip"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/${MY_PN}

src_unpack() {
	unpack_makeself ${RUN_FILE}
	tar -xjf ${DATA_FILE} || die "tar failed"

	for skin in {battlescar,midniteskins} ; do
		unzip "${DISTDIR}/${skin}.zip" || die "unzip ${skin} failed"
	done
}

src_install() {
	local cpu_dir="x86"
	use amd64 && cpu_dir="x86_64"

	# Set up this directory to look like the install directory
	cp -r engine/${cpu_dir}/* . || die
	cp -r bin/Linux/${cpu_dir}/glibc-2.1/* . || die

	doicon ${MY_PN}.xpm
	games_make_wrapper ${MY_PN}-ded ./AlienArenaDedicated "${dir}" "${dir}"
	# Always install the OpenGL version
	games_make_wrapper ${MY_PN} ./AlienArena "${dir}" "${dir}"
	if use sdl ; then
		cp AlienArena AlienArena.sdl
		sed -i AlienArena.sdl -e "s:crx:crx.sdl:"
		games_make_wrapper ${MY_PN}-sdl ./AlienArena.sdl "${dir}" "${dir}"
		# Distinguish between OpenGL and SDL versions
		make_desktop_entry ${MY_PN} "Alien Arena - OpenGL" ${MY_PN}.xpm
		make_desktop_entry ${MY_PN}-sdl "Alien Arena - SDL" ${MY_PN}.xpm
	else
		make_desktop_entry ${MY_PN} "Alien Arena" ${MY_PN}.xpm
	fi

	# Install
	insinto "${dir}"
	exeinto "${dir}"
	doins -r arena botinfo data1 *.txt || die
	doexe AlienArena* crded crx crx.sdl || die

	prepgamesdirs
}

pkg_postinst() {
	if use sdl ; then
		einfo "To play the game, run:  ${MY_PN} or ${MY_PN}-sdl"
		echo
	fi

	games_pkg_postinst
}