wormux-0.7_beta3.ebuild

wormux-0.7_beta3.ebuild (text/plain), 1.46 KB, created by Paul Bredbury on 2006-02-08 12:14:11 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PV=${PV/_/}

DESCRIPTION="Free Worms clone"
HOMEPAGE="http://www.wormux.org/"
SRC_URI="http://download.gna.org/${PN}/${PN}-${MY_PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="nls debug"

RDEPEND=">=dev-cpp/glibmm-2.8.1
	>=dev-cpp/libxmlpp-2.12.0
	>=dev-libs/libsigc++-2.0.16
	>=dev-libs/libxml2-2.6.23-r1
	>=media-libs/freetype-2.1.10
	>=media-libs/jpeg-6b-r5
	>=media-libs/libmikmod-3.1.11-r1
	>=media-libs/libogg-1.1.2
	>=media-libs/libpng-1.2.8
	>=media-libs/libsdl-1.2.8-r1
	>=media-libs/libvorbis-1.1.0
	>=media-libs/sdl-gfx-2.0.13-r1
	>=media-libs/sdl-image-1.2.3-r1
	>=media-libs/sdl-mixer-1.2.6
	>=media-libs/sdl-ttf-2.0.7
	>=media-libs/smpeg-0.4.4-r6
	>=media-libs/tiff-3.7.3
	sys-libs/zlib
	virtual/libc
	|| (
		(
			x11-libs/libX11
			x11-libs/libXau
			x11-libs/libXdmcp
			x11-libs/libXext )
		virtual/x11 )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${PN}-${MY_PV}

src_unpack() {
	unpack ${A}
	cd "${S}"

	if use nls ; then
		sed -i \
			-e '/^localedir =/s:=.*:=/usr/share/locale:' \
			po/Makefile.in || die "sed localedir failed"
	fi
}

src_compile() {
	egamesconf \
		$(use_enable nls) \
		$(use_enable debug) \
		|| die "egamesconf failed"
	emake || die "emake failed"
}

src_install() {
	make install DESTDIR="${D}" || die "make install failed"
	dodoc AUTHORS README

	prepgamesdirs
}