app-crypt/signing-party/signing-party-0.4.4.2.ebuild (v.1)

signing-party-0.4.4.2.ebuild (text/plain), 2.15 KB, created by Martin von Gagern on 2006-02-03 06:11:58 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PV="${PV%.*}"
MY_PR="${PV##*.}"
MY_PN="signing-party"
MY_P="${MY_PN}_${MY_PV}"
MY_URL="mirror://debian/pool/main/${MY_PN:0:1}/${MY_PN}/${MY_P}"

DESCRIPTION="A collection of OpenPGP related scripts, for keysigning, party preparation etc."
HOMEPAGE="http://pgp-tools.alioth.debian.org/"
SRC_URI="${MY_URL}.orig.tar.gz"
[[ $MY_PR != 0 ]] && SRC_URI="${SRC_URI} ${MY_URL}-${MY_PR}.diff.gz"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="iconv recode"

# parts have different license, see debian/copyright in tar
LICENSE="GPL-2"

DEPEND=""

RDEPEND="dev-lang/perl
	dev-perl/GnuPG-Interface
	dev-perl/MIME-tools
	dev-perl/text-template
	>=dev-perl/MailTools-1.62
	>=app-crypt/gnupg-1.3.92
	virtual/mailx
	iconv? ( dev-perl/Text-Iconv )
	recode? ( app-text/recode )"

	# other Debian recommendations, see debian/control in tar:
	# || ( dev-perl/Text-Iconv dev-perl/libintl-perl app-text/recode )
	# virtual/mta
	# dev-util/dialog

S="${WORKDIR}/${MY_PN}-${MY_PV}"

src_unpack() {
	unpack ${A}
	[[ $MY_PR != 0 ]] && epatch "${MY_P}-${MY_PR}.diff"
	sed -i -e "s:/usr/share/doc/signing-party/caff/caffrc.sample:/usr/share/doc/${P}/caff/caffrc.sample.gz:g" ${S}/caff/caff
}

src_compile() {
	emake || die "emake failed"
}

src_install() {
	# debian/install looks like this:
	# caff/caff usr/bin
	# caff/pgp-clean usr/bin
	# caff/pgp-fixkey usr/bin
	# gpglist/gpglist usr/bin
	# gpgsigs/gpgsigs usr/bin
	# gpg-key2ps/gpg-key2ps usr/bin
	# gpg-mailkeys/gpg-mailkeys usr/bin
	# keylookup/keylookup usr/bin

	while read SRC DST; do
		[[ $DST == usr/bin ]] || die "unexpected target location"
		dobin ${SRC}
	done < debian/install

	doman */*.1

	dodoc README TODO debian/NEWS.Debian debian/changelog
	docinto caff
	dodoc caff/README* caff/TODO caff/THANKS caff/caffrc.sample
	docinto gpgsigs/examples
	dodoc gpgsigs/gpgsigs-lt2k5*.txt
	docinto keylookup
	dodoc keylookup/COPYING keylookup/NEWS
	docinto gpg-mailkeys
	dodoc gpg-mailkeys/README* gpg-mailkeys/example.gpg-mailkeysrc
	docinto gpg-key2ps
	dodoc gpg-key2ps/README
}